创建公共安全连接 Looker (Google Cloud Core) 实例

本页面讨论了如何预配配置为使用公共安全连接的 Looker (Google Cloud Core) 生产实例或 非生产实例。

如果要创建专用连接实例，则必须在创建实例时分配配置。如需了解如何创建专用连接实例，请按照创建 Looker (Google Cloud Core) Private Service Connect 实例或创建专用连接（专用服务访问通道）Looker (Google Cloud Core) 实例文档页面上的步骤操作，而不是按照以下步骤操作。

准备工作

  1. 与销售团队合作，确保完成您的年度合同，并在您的项目中分配配额。
  2. 确保您的 Google Cloud 项目已启用结算功能。
  3. 在 Google Cloud 控制台的“项目选择器”页面上，创建 Google Cloud 项目或前往现有项目。

    前往“项目选择器”页面

  4. 在 Google Cloud 控制台中为您的项目启用 Looker API。启用 API 时，您可能需要刷新控制台页面才能确认相应 API 已启用。

    启用 API

  5. 如果要使用 VPC Service Controls，则必须创建 专用连接（专用服务访问通道） 实例，而不是公共安全连接实例。

所需角色

如需获得创建 Looker (Google Cloud Core) 实例所需的权限，请让您的管理员为您授予Looker Admin (roles/looker.admin) IAM 角色，该角色位于实例将驻留的项目中。如需详细了解如何授予角色，请参阅管理对项目、文件夹和组织的访问权限。

您也可以通过自定义 角色或其他预定义 角色来获取所需的权限。

如果您想设置客户管理的加密密钥 (CMEK)，可能还需要其他 IAM 角色。如需了解详情，请访问 Cloud Key Management Service 文档的“使用 IAM 进行访问权限控制”页面。

创建 Looker (Google Cloud Core) 实例

Looker (Google Cloud Core) 生成新实例大约需要 60 分钟。

如需创建 Looker (Google Cloud Core) 实例，请选择以下选项之一：

控制台

  1. 在 Google Cloud 控制台中，从您的项目前往 Looker (Google Cloud Core) 产品页面。如果您已在此项目中创建 Looker (Google Cloud Core) 实例，系统会打开实例 页面。

    前往 Looker (Google Cloud Core)

  2. 点击创建实例 。
  3. 在实例名称 部分，为 Looker (Google Cloud Core) 实例提供名称。实例名称在创建后不会与 Looker (Google Cloud Core) 实例的网址关联。实例创建完成后，此字段便无法更改。
  4. 在区域 部分，从下拉菜单中选择相应选项，以托管 Looker (Google Cloud Core) 实例。选择与订阅合同中的区域匹配的区域，因为这是分配项目配额的位置。Looker (Google Cloud Core) 位置文档页面列出了可用的区域。实例创建后，此区域便无法更改。

  5. 在版本 部分，根据贵组织的需求设置实例版本。版本类型会影响实例可用的某些功能。请确保您选择的版本类型与您的年度合同中列出的版本类型相同，并且您已为该版本类型分配配额。以下是版本选项：

    • 标准版：Looker (Google Cloud Core) 平台，适合用户少于 50 人的小型组织或团队
    • 企业版：Looker (Google Cloud Core) 平台，具有增强型安全功能，适用于各种内部 BI 和分析应用场景
    • 嵌入版：Looker (Google Cloud Core) 平台，适合用于大规模部署和维护可靠的外部分析和自定义应用
    • 非生产版本：如果您需要预演和测试环境，请选择其中一个非生产版本。如需了解详情，请参阅非生产实例文档。
    • 试用版：试用版与相应的生产版本具有相同的功能支持，但试用版的有效期为 90 天。

    实例创建完成后，版本便无法更改。如果要更改版本，可以使用 导入和导出 功能将 Looker (Google Cloud Core) 实例数据移到配置了不同版本的新实例中。

  6. 在自定义实例 部分，点击显示配置选项 ，以显示一组您可以为实例自定义的其他设置。

  7. 在连接 部分，选择使用公共安全连接 。公共安全连接设置会分配一个可通过互联网访问的外部 IP 地址，并且适用于所有版本类型。

  8. 如果您要创建企业版 或嵌入版 实例，您将看到加密 部分。在加密 部分，您可以选择要在实例上使用的加密类型。以下加密选项可用：

  9. 在发布渠道 部分，选择最符合您需求的发布渠道：

    • 快速：最早使用功能。建议将此渠道设为非生产实例的默认渠道。
    • 常规：稳定性适中。建议为生产实例选择此渠道。
    • 无渠道：无发布渠道。在预览期间，“无渠道”是默认渠道。

  10. 在 维护期 部分，您可以选择 指定星期几和小时，Looker (Google Cloud Core) 会在此时安排维护。

  11. 在 拒绝维护期 部分，您可以选择 指定 Looker (Google Cloud Core) 不安排维护的时间段。如果您同时将实例注册到快速发布渠道，或者将加速安全补丁 (ASP) 配置标志与常规发布渠道搭配使用，则无法设置拒绝维护期。

  12. 在 Gemini in Looker 部分，您可以选择为 Looker (Google Cloud Core) 实例提供 Gemini in Looker 功能。如需启用 Gemini in Looker，请选择 Gemini，然后选择 可信测试员功能。启用可信测试员功能 后，用户可以使用 Gemini in Looker 中的可信测试员功能。您可以通过 Gemini in Looker 预览表单 按用户申请使用非公开的可信测试员功能。您必须启用此设置，才能在正式发布前的预览期间使用 Gemini。您可以选择启用可信测试员数据使用 。启用此设置后，即表示您同意 Google 按照 Gemini for Google Cloud 可信测试员计划条款中所述的方式使用您的数据。如需为 Looker (Google Cloud Core) 实例停用 Gemini，请清除 Gemini 设置。

  13. 在 Knowledge Catalog 集成 部分，如果您不希望 Looker (Google Cloud Core) 与 Knowledge Catalog 集成，可以选择勾选选择停用 Knowledge Catalog 集成 复选框。默认情况下，Looker (Google Cloud Core) 和 Knowledge Catalog 会集成。

  14. 点击创建 。

gcloud

  1. 如果您使用的是 CMEK，请先 创建 Looker 服务账号，然后按照说明设置 CMEK。

  2. 使用 gcloud looker instances create 命令创建实例：

    gcloud looker instances create INSTANCE_NAME \
--project=PROJECT_ID \
--region=REGION \
--edition=EDITION \
[--release-channel=RELEASE_CHANNEL]\
--public-ip-enabled \
--async

    替换以下内容：

    • INSTANCE_NAME：Looker (Google Cloud Core) 实例的名称；它不会与实例网址关联。
    • PROJECT_ID：您要在其中创建 Looker (Google Cloud Core) 实例的 Google Cloud 项目的名称。
    • REGION：Looker (Google Cloud Core) 实例托管的区域。选择与订阅合同中的区域匹配的区域。Looker (Google Cloud Core) 位置文档页面列出了可用的区域。实例创建后，此区域便无法更改。
    • EDITION：实例的版本、环境类型（生产或 非生产）以及是否为 试用版。其可用值包括 core-standard-annual、core-enterprise-annual、core-embed-annual、nonprod-core-standard-annual、nonprod-core-enterprise-annual、nonprod-core-embed-annual、core-trial-standard、core-trial-enterprise 和 core-trial-embed。实例创建完成后，版本便无法更改。如果要更改版本，可以使用 导入和导出 功能将 Looker (Google Cloud Core) 实例数据移到配置了不同版本的新实例中。
    • RELEASE_CHANNEL：实例的发布渠道。可用值包括 rapid、regular 和 no-channel。在预览期间，默认值为 no-channel。如果您未在 create 命令中添加此标志，系统将使用默认渠道创建实例。此功能处于预览阶段。

    另请添加以下标志：

    • --public-ip-enabled 用于启用公共安全连接。
    • 创建 Looker (Google Cloud Core) 实例时，建议使用 --async。

  3. 您可以添加更多参数来应用其他实例设置： 

    [--maintenance-window-day=MAINTENANCE_WINDOW_DAY
      --maintenance-window-time=MAINTENANCE_WINDOW_TIME]
[--deny-maintenance-period-end-date=DENY_MAINTENANCE_PERIOD_END_DATE
      --deny-maintenance-period-start-date=DENY_MAINTENANCE_PERIOD_START_DATE
      --deny-maintenance-period-time=DENY_MAINTENANCE_PERIOD_TIME]
[--kms-key=KMS_KEY_ID]
[--accelerated-security-patch-enabled]
[--no-accelerated-security-patch-enabled]
[--fips-enabled]
[--catalog-integration-enabled]
[--no-catalog-integration-enabled]

    替换以下内容：

    • MAINTENANCE_WINDOW_DAY：必须是以下值之一：friday、monday、saturday、sunday、thursday、tuesday、wednesday。如需详细了解维护窗口设置，请参阅管理 Looker (Google Cloud Core) 的维护政策文档页面。
    • MAINTENANCE_WINDOW_TIME 和 DENY_MAINTENANCE_PERIOD_TIME：必须采用 24 小时制 UTC 时间格式（例如 13:00、17:45）。
    • DENY_MAINTENANCE_PERIOD_START_DATE 和 DENY_MAINTENANCE_PERIOD_END_DATE：必须采用 YYYY-MM-DD 格式。如果您同时将实例注册到快速发布渠道，或者将加速安全补丁 (ASP) 配置标志与常规发布渠道搭配使用，则无法设置拒绝维护期。
    • KMS_KEY_ID：必须是在设置 客户管理的加密密钥 (CMEK) 时创建的密钥。

    以下标志可启用其他设置：

Terraform

使用以下 Terraform 资源预配具有基本功能的 标准版 Looker (Google Cloud Core) 实例：

# Creates a Standard edition Looker (Google Cloud core) instance with basic functionality enabled.
resource "google_looker_instance" "main" {
  name             = "my-instance"
  platform_edition = "LOOKER_CORE_STANDARD"
  region           = "us-central1"
  oauth_config {
    client_id     = "my-client-id"
    client_secret = "my-client-secret"
  }
}

使用以下 Terraform 资源预配应用了其他设置的 标准版 Looker (Google Cloud Core) 实例：

# Creates a Standard edition Looker (Google Cloud core) instance with full functionality enabled.

resource "google_looker_instance" "main" {
  name              = "my-instance"
  platform_edition  = "LOOKER_CORE_STANDARD"
  region            = "us-central1"
  public_ip_enabled = true
  admin_settings {
    allowed_email_domains = ["google.com"]
  }
  // User metadata config is only available when platform edition is LOOKER_CORE_STANDARD.
  user_metadata {
    additional_developer_user_count = 10
    additional_standard_user_count  = 10
    additional_viewer_user_count    = 10
  }
  maintenance_window {
    day_of_week = "THURSDAY"
    start_time {
      hours   = 22
      minutes = 0
      seconds = 0
      nanos   = 0
    }
  }
  deny_maintenance_period {
    start_date {
      year  = 2050
      month = 1
      day   = 1
    }
    end_date {
      year  = 2050
      month = 2
      day   = 1
    }
    time {
      hours   = 10
      minutes = 0
      seconds = 0
      nanos   = 0
    }
  }
  oauth_config {
    client_id     = "my-client-id"
    client_secret = "my-client-secret"
  }
}

使用以下 Terraform 资源预配具有专用 网络连接的 企业版 Looker (Google Cloud Core) 实例：

# Creates an Enterprise edition Looker (Google Cloud core) instance with full, Private IP functionality.
resource "google_looker_instance" "main" {
  name               = "my-instance"
  platform_edition   = "LOOKER_CORE_ENTERPRISE_ANNUAL"
  region             = "us-central1"
  private_ip_enabled = true
  public_ip_enabled  = false
  reserved_range     = google_compute_global_address.main.name
  consumer_network   = data.google_compute_network.main.id
  admin_settings {
    allowed_email_domains = ["google.com"]
  }
  encryption_config {
    kms_key_name = google_kms_crypto_key.main.id
  }
  maintenance_window {
    day_of_week = "THURSDAY"
    start_time {
      hours   = 22
      minutes = 0
      seconds = 0
      nanos   = 0
    }
  }
  deny_maintenance_period {
    start_date {
      year  = 2050
      month = 1
      day   = 1
    }
    end_date {
      year  = 2050
      month = 2
      day   = 1
    }
    time {
      hours   = 10
      minutes = 0
      seconds = 0
      nanos   = 0
    }
  }
  oauth_config {
    client_id     = "my-client-id"
    client_secret = "my-client-secret"
  }
  depends_on = [
    google_service_networking_connection.main,
    google_kms_crypto_key.main
  ]
}

resource "google_kms_key_ring" "main" {
  name     = "keyring-example"
  location = "us-central1"
}

resource "google_kms_crypto_key" "main" {
  name     = "crypto-key-example"
  key_ring = google_kms_key_ring.main.id
}

resource "google_service_networking_connection" "main" {
  network                 = data.google_compute_network.main.id
  service                 = "servicenetworking.googleapis.com"
  reserved_peering_ranges = [google_compute_global_address.main.name]
}

resource "google_compute_global_address" "main" {
  name          = "looker-range"
  purpose       = "VPC_PEERING"
  address_type  = "INTERNAL"
  prefix_length = 20
  network       = data.google_compute_network.main.id
}

data "google_project" "main" {}

data "google_compute_network" "main" {
  name = "default"
}

resource "google_kms_crypto_key_iam_member" "main" {
  crypto_key_id = google_kms_crypto_key.main.id
  role          = "roles/cloudkms.cryptoKeyEncrypterDecrypter"
  member        = "serviceAccount:service-${data.google_project.main.number}@gcp-sa-looker.iam.gserviceaccount.com"
}

如需了解如何应用或移除 Terraform 配置，请参阅 基本 Terraform 命令。

实例创建过程一旦启动，便无法暂停或终止。成功预配 Terraform 资源后，终端将输出以下消息：

Creation complete after XmXs [id=projects/PROJECT-ID/locations/REGION/instances/my-instance-randomly-generated-name]


Apply complete! Resources: X added, X changed, X destroyed.

创建实例时，您可以在控制台内的实例 页面上查看其状态。您还可以点击 Google Cloud 控制台菜单中的通知图标，查看实例创建活动。

创建公共安全连接实例后，实例的公共网址将显示在实例 页面的实例网址 列中。

创建实例后，您可以前往实例 页面上显示的实例网址，然后使用 Google 账号登录，即可查看该实例。

您可以访问实例详情页面，然后点击修改，以修改实例设置，包括添加手动 OAuth 凭据（如果需要）。

排查实例创建问题

如需获得问题排查帮助，请参阅排查 Looker (Google Cloud Core) 实例创建失败问题文档页面。

后续步骤