DATETIME_DIFF

Devuelve el número de límites fraccionarios entre dos fechas.

Ejemplo de uso

DATETIME_DIFF(Order Date, Ship Date, DAY)

Sintaxis

DATETIME_DIFF( date_expression, date_expression, part )

Parámetros

  • date_expression - Es un campo o expresión de fecha o de fecha y hora. Si la primera expresión de fecha se encuentra antes de la segunda, el resultado será cero o negativo.
  • part - Es la parte de la hora que se mostrará. DATETIME_DIFF admite las siguientes partes:
    • MICROSECOND: Está disponible para campos o expresiones de fecha y hora.
    • MILLISECOND: Está disponible para campos o expresiones de fecha y hora.
    • SECOND: Está disponible para campos o expresiones de fecha y hora.
    • MINUTE: Está disponible para campos o expresiones de fecha y hora.
    • HOUR: Está disponible para campos o expresiones de fecha y hora.
    • DAY
    • WEEK: Esta parte de la fecha comienza el día domingo.
    • ISOWEEK: Utiliza límites de semana ISO 8601. Las semanas ISO comienzan el lunes.
    • MONTH
    • QUARTER
    • YEAR
    • ISOYEAR: Utiliza el límite de año de numeración de semanas ISO 8601. El límite del año ISO es el lunes de la primera semana cuyo jueves pertenece al año calendario gregoriano correspondiente.

Tipo de datos que se muestran

Número (entero)

Ejemplos

En el segundo y tercer ejemplo de la siguiente tabla, se muestra el resultado de DATETIME_DIFF para dos valores de fecha que están separados por 24 horas. DATETIME_DIFF con la parte WEEK muestra 1 porque DATETIME_DIFF cuenta el número de límites de parte en este rango de valores de fecha. Cada WEEK comienza el domingo, por lo que hay un límite de parte entre el sábado, 2017-10-14 00:00:00, y el domingo, 2017-10-15 00:00:00.

Fórmula de ejemplo Salida
DATETIME_DIFF( DATETIME "2010-07-07 10:20:00", DATETIME "2008-12-25 15:30:00", DAY ) 559
DATETIME_DIFF( DATETIME "2017-10-15 00:00:00", DATETIME "2017-10-14 00:00:00", DAY )

1

DATETIME_DIFF( DATETIME "2017-10-15 00:00:00", DATETIME "2017-10-14 00:00:00", WEEK ) 1

En el siguiente ejemplo, se muestra el resultado de DATETIME_DIFF para dos fechas en años diferentes. DATETIME_DIFF con la parte de fecha YEAR muestra 3 porque cuenta el número de límites del año calendario gregoriano entre los dos valores de fecha. DATETIME_DIFF con la parte de fecha ISOYEAR muestra 2 porque el segundo valor de fecha pertenece al año ISO 2015. El primer jueves del año calendario 2015 fue 2015-01-01, por lo que el año ISO 2015 comienza el lunes anterior, 2014-12-29.

Fórmula de ejemplo Salida
DATETIME_DIFF(DATETIME '2017-12-30 00:00:00', DATETIME '2014-12-30 00:00:00', YEAR) 3
DATETIME_DIFF(DATETIME '2017-12-30 00:00:00', DATETIME '2014-12-30 00:00:00', ISOYEAR)

2

En el siguiente ejemplo, se muestra el resultado de DATETIME_DIFF durante dos días seguidos. La primera fecha es un lunes y la segunda es un domingo. DATETIME_DIFF con la parte de fecha ISOWEEK también muestra 1 porque las semanas ISO comienzan el lunes.

Fórmula de ejemplo Salida
DATETIME_DIFF(DATE '2017-12-18', DATE '2017-12-17', WEEK) 0
DATETIME_DIFF(DATE '2017-12-18', DATE'2017-12-17', ISOWEEK) 1

Notas

Esta función no está disponible para los tipos de fecha del modo de compatibilidad.