DATETIME_DIFF

Affiche le nombre de limites de partie entre deux dates.

Exemple d'utilisation

DATETIME_DIFF(Order Date, Ship Date, DAY)

Syntaxe

DATETIME_DIFF( date_expression, date_expression, part )

Paramètres

  • date_expression : un champ ou une expression de type "Date" ou "Date et heure" Si la première expression de date est antérieure à la deuxième expression de date, le résultat est zéro ou négatif.
  • part : l'élément de temps à renvoyer. DATETIME_DIFF accepte les éléments suivants :
    • MICROSECOND : disponible pour les champs ou les expressions de type "Date et heure".
    • MILLISECOND : disponible pour les champs ou les expressions de type "Date et heure".
    • SECOND : disponible pour les champs ou les expressions de type "Date et heure".
    • MINUTE : disponible pour les champs ou les expressions de type "Date et heure".
    • HOUR : disponible pour les champs ou les expressions de type "Date et heure".
    • DAY
    • WEEK : cette partie de date commence le dimanche.
    • ISOWEEK : utilise les limites de semaine ISO 8601. Les semaines ISO commencent le lundi.
    • MONTH
    • QUARTER
    • YEAR
    • ISOYEAR : utilise la limite d'année à numérotation de semaines ISO 8601. La limite d'année ISO est le lundi de la première semaine où le jeudi appartient à l'année civile grégorienne correspondante.

Type des données renvoyées

Nombre (entier)

Exemples

Les deuxième et troisième exemples du tableau suivant affichent le résultat de DATETIME_DIFF pour deux valeurs de date séparées de 24 heures. DATETIME_DIFF avec l'élément WEEK renvoie 1, car DATETIME_DIFF compte le nombre de limites d'élément dans cette plage de valeurs de date. Chaque WEEK commence le dimanche. Il existe donc une limite d'élément entre le samedi 2017-10-14 00:00:00 et le dimanche 2017-10-15 00:00:00.

Exemple de formule Sortie
DATETIME_DIFF( DATETIME "2010-07-07 10:20:00", DATETIME "2008-12-25 15:30:00", DAY ) 559
DATETIME_DIFF( DATETIME "2017-10-15 00:00:00", DATETIME "2017-10-14 00:00:00", DAY )

1

DATETIME_DIFF( DATETIME "2017-10-15 00:00:00", DATETIME "2017-10-14 00:00:00", WEEK ) 1

L'exemple suivant montre le résultat de DATETIME_DIFF pour deux dates avec des années différentes. DATETIME_DIFF avec l'élément de date YEAR renvoie 3, car elle compte le nombre de limites de l'année civile grégorienne entre les deux dates. DATETIME_DIFF avec l'élément de date ISOYEAR renvoie 2, car la seconde valeur de date appartient à l'année ISO 2015. Le premier jeudi de l'année civile 2015 était le 1er janvier 2015 (2015-01-01), donc l'année ISO 2015 commence le lundi précédent, soit le 29 décembre 2014 (2014-12-29).

Exemple de formule Sortie
DATETIME_DIFF(DATETIME '2017-12-30 00:00:00', DATETIME '2014-12-30 00:00:00', YEAR) 3
DATETIME_DIFF(DATETIME '2017-12-30 00:00:00', DATETIME '2014-12-30 00:00:00', ISOYEAR)

2

L'exemple suivant montre le résultat de DATETIME_DIFF pour deux jours consécutifs. La première date tombe un lundi et la seconde un dimanche. DATETIME_DIFF avec l'élément de date ISOWEEK renvoie également 1, car les semaines ISO commencent le lundi.

Exemple de formule Sortie
DATETIME_DIFF(DATE '2017-12-18', DATE '2017-12-17', WEEK) 0
DATETIME_DIFF(DATE '2017-12-18', DATE'2017-12-17', ISOWEEK) 1

Remarques

Cette fonction n'est pas disponible pour les types de dates en mode de compatibilité.