Google uses AI technology to translate content into your preferred language. AI translations can contain errors.

태그를 사용하여 리소스 액세스 제어

이 문서에서는 태그를 사용하여 Cloud Monitoring 대시보드 및 알림 정책에 대한 액세스를 제어하는 방법을 설명합니다. 태그는 리소스에 연결하기 위해 생성하는 키-값 쌍입니다. 태그를 Identity and Access Management (IAM) 조건 또는 거부 정책과 결합하면 특정 대시보드와 알림 정책을 수정하거나 삭제할 수 있는 사용자를 제한할 수 있습니다.

액세스 제어 패턴

다음 패턴 중 하나를 사용하여 대시보드 및 알림 정책에 대한 액세스 제어를 구현할 수 있습니다.

Terraform 관리 리소스에 대한 액세스 제어: 태그가 지정된 리소스가 Terraform에 의해서만 수정될 수 있도록 태그와 IAM 거부 정책을 사용합니다. Terraform 관리 리소스는 Google Cloud 콘솔이나 다른 클라이언트를 통한 승인되지 않은 수동 변경으로부터 보호됩니다.
팀 관리 리소스에 대한 액세스 제어: 팀별 태그와 조건부 IAM 역할 부여를 사용하여 특정 팀의 구성원만 팀 관리 대시보드와 알림 정책을 수정하거나 삭제할 수 있도록 합니다.

Terraform 관리 리소스 보호

이 섹션에서는 태그가 지정된 대시보드와 알림 정책을 Terraform을 사용하도록 구성된 서비스 계정을 사용해서만 수정하거나 삭제할 수 있도록 태그와 IAM 거부 정책을 사용하는 방법을 설명합니다.

시작하기 전에

프로젝트의 태그 및 IAM 거부 정책을 구성하는 데 필요한 권한을 얻으려면 관리자에게 프로젝트 또는 조직에 대한 다음 IAM 역할을 부여해 달라고 요청하세요.

태그 만들기: 태그 관리자 (roles/resourcemanager.tagAdmin)
IAM 거부 정책 관리: 거부 정책 관리자 (roles/iam.denyAdmin)

역할 부여에 대한 자세한 내용은 프로젝트, 폴더, 조직에 대한 액세스 관리를 참조하세요.

커스텀 역할이나 다른 사전 정의된 역할을 통해 필요한 권한을 얻을 수도 있습니다.

거부 정책을 사용하여 리소스 보호

Google Cloud 콘솔

리소스가 Terraform에 의해 관리됨을 나타내는 태그를 만듭니다. 예를 들어 태그 값 terraform_only이 있는 태그 키 edit_restriction를 만듭니다.
리소스에 edit_restriction:terraform_only 태그가 있는 경우 Terraform 서비스 계정을 제외한 모든 주 구성원의 업데이트 및 삭제 권한을 거부하는 IAM 거부 정책을 만듭니다.

거부 정책에는 다음 구성이 포함되어야 합니다.
- 거부할 권한:
  - monitoring.dashboards.update
  - monitoring.dashboards.delete
  - monitoring.alertPolicies.update
  - monitoring.alertPolicies.delete
- 조건: 리소스에 edit_restriction:terraform_only 태그가 있어야 합니다.
- 예외: 거부 규칙의 예외 목록에 Terraform 서비스 계정의 주 구성원 식별자를 추가합니다.
보호할 대시보드 또는 알림 정책을 만든 다음 리소스에 태그를 연결합니다.

Terraform

Terraform을 사용하여 제한사항을 구성하려면 다음을 실행하세요.

프로젝트에 Terraform을 설치하고 구성합니다.
태그 키와 태그 값을 만듭니다.
IAM 거부 정책을 만듭니다.
보호할 알림 정책 또는 대시보드를 만듭니다. 자세한 내용은 Terraform을 사용하여 알림 정책 만들기 및 Terraform을 사용하여 대시보드 만들기를 참고하세요.
태그를 리소스에 바인딩합니다. Terraform을 사용하여 대시보드 또는 알림 정책에 태그를 연결하려면 google_tags_tag_binding를 사용하여 태그 바인딩 리소스를 만듭니다.

예를 들어 다음 Terraform 구성은 다음 작업을 실행합니다.

태그 키와 값을 만듭니다.
거부 정책을 만듭니다.
알림 정책을 만듭니다.
태그를 알림 정책에 바인딩합니다.

동일한 명령어에서 리소스를 만들고 태그를 바인딩할 수는 없습니다. 리소스와 태그 바인딩을 별도로 만들어야 합니다.

# Create the tag key.
resource "google_tags_tag_key" "lock_key" {
  parent     = "projects/PROJECT_ID"
  short_name = "edit_restriction"
}

# Create the tag value.
resource "google_tags_tag_value" "restricted_value" {
  parent     = "tagKeys/${google_tags_tag_key.lock_key.name}"
  short_name = "terraform_only"
}

# Define the IAM deny policy.
resource "google_iam_deny_policy" "terraform_lock" {
  parent       = urlencode(
    "cloudresourcemanager.googleapis.com/projects/PROJECT_ID"
  )
  name         = "terraform-exclusive-lock"
  display_name = "Deny modifications except for Terraform service account"

  rules {
    deny_rule {
      denied_principals = ["principalSet://goog/public:all"]

      # Exempt the Terraform service account.
      exception_principals = [
        join("", [
          "principal://iam.googleapis.com/projects/-/",
          "serviceAccounts/TERRAFORM_SERVICE_ACCOUNT_EMAIL"
        ])
      ]

      denied_permissions = [
        "monitoring.googleapis.com/alertPolicies.update",
        "monitoring.googleapis.com/alertPolicies.delete",
        "monitoring.googleapis.com/dashboards.update",
        "monitoring.googleapis.com/dashboards.delete"
      ]

      denial_condition {
        title      = "is_restricted_resource"
        expression = join("", [
          "resource.matchTag(",
          "'PROJECT_ID/edit_restriction', ",
          "'terraform_only')"
        ])
      }
    }
  }
}

# Create the alerting policy.
resource "google_monitoring_alert_policy" "protected_policy" {
  display_name = "Restricted Alert Policy"
  combiner     = "OR"
  conditions {
    display_name = "High CPU"
    condition_threshold {
      filter     = join(" AND ", [
        "metric.type=\"compute.googleapis.com/instance/cpu/utilization\"",
        "resource.type=\"gce_instance\""
      ])
      duration   = "60s"
      comparison = "COMPARISON_GT"
      threshold_value = 0.9
    }
  }
}

# Bind the tag to the alerting policy.
resource "google_tags_tag_binding" "policy_binding" {
  parent    = join("", [
    "//monitoring.googleapis.com/",
    google_monitoring_alert_policy.protected_policy.name
  ])
  tag_value = google_tags_tag_value.restricted_value.id
}

팀 범위 액세스 구성

여러 팀의 애플리케이션을 모니터링하는 프로젝트의 관리자라고 가정해 보겠습니다. 팀 구성원이 대시보드와 알림 정책을 만들 수 있지만 자신의 팀 리소스만 수정할 수 있도록 하려고 합니다. 팀 구성원에게 광범위한 모니터링 편집자 역할(roles/monitoring.editor)을 부여하면 프로젝트의 모든 모니터링 리소스를 수정할 수 있는 권한이 부여되므로 이 역할을 부여하지 않는 것이 좋습니다.

이 섹션에서는 태그를 사용하여 팀 소유 대시보드 및 알림 정책만 수정하는 데 필요한 권한을 팀 구성원에게 부여하는 방법을 보여줍니다.

시작하기 전에

프로젝트의 태그와 IAM 역할을 구성하는 데 필요한 권한을 얻으려면 관리자에게 프로젝트 또는 조직에 대한 다음 IAM 역할을 부여해 달라고 요청하세요.

태그 만들기: 태그 관리자 (roles/resourcemanager.tagAdmin)
맞춤 역할 만들기: 역할 관리자 (roles/iam.roleAdmin)
프로젝트 역할 관리: 프로젝트 IAM 관리자 (roles/resourcemanager.projectIamAdmin)

역할 부여에 대한 자세한 내용은 프로젝트, 폴더, 조직에 대한 액세스 관리를 참조하세요.

커스텀 역할이나 다른 사전 정의된 역할을 통해 필요한 권한을 얻을 수도 있습니다.

팀별 태그 적용

Google Cloud 콘솔

각 팀에 대해 태그를 만듭니다. 새 태그 키를 만든 다음 해당 키의 태그 값을 만듭니다. 예를 들어 값 team_a 및 team_b로 owner라는 태그 키를 만들면 owner:team_a 및 owner:team_b이라는 두 개의 태그가 생성됩니다. 각 태그의 태그 키 ID와 값 ID를 기록합니다.
'대시보드 및 알림 정책 생성자'라는 맞춤 역할을 만들고 다음 권한을 추가합니다.
- monitoring.alertPolicies.create
- monitoring.alertPolicies.createTagBinding
- monitoring.dashboards.create
- monitoring.dashboards.createTagBinding
- resourcemanager.tagValueBindings.create
이 역할을 사용하면 대시보드와 알림 정책을 만들고 태그를 적용할 수 있습니다.
모든 팀 구성원에게 다음 역할을 부여합니다.
- 대시보드 및 알림 정책 작성자 (개발자가 만든 맞춤 역할)
- 모니터링 뷰어(roles/monitoring.viewer)
- 태그 뷰어 (roles/resourcemanager.tagViewer)
각 팀에 대해 팀 구성원에게 IAM 조건이 연결된 다음 역할을 부여합니다.
- 태그 사용자 (roles/resourcemanager.tagUser): 팀의 태그를 리소스에 적용할 수 있습니다.
- 팀의 태그가 있는 대시보드와 알림 정책을 수정할 수 있는 모니터링 편집자 (roles/monitoring.editor)
다음과 같이 역할 부여에 IAM 조건을 추가합니다.
- 조건 유형: Tag
- 운영자: has value ID
- keyID: KEY_ID
- valueID: TEAM_VALUE_ID
Resource Manager에서 태그 키 ID와 값 ID를 찾습니다. 자세한 내용은 태그가 지정된 리소스에 대한 액세스를 참고하세요.
액세스를 제한할 대시보드 또는 알림 정책을 만든 다음 리소스에 태그를 연결합니다.

Terraform

Terraform을 사용하여 팀 범위 액세스를 구성하려면 다음을 실행하세요.

프로젝트에 Terraform을 설치하고 구성합니다.
각 팀의 태그 키와 태그 값을 만듭니다.
맞춤 역할을 만들고 다음 권한을 추가합니다.
- monitoring.alertPolicies.create
- monitoring.alertPolicies.createTagBinding
- monitoring.dashboards.create
- monitoring.dashboards.createTagBinding
- resourcemanager.tagValueBindings.create
모든 구성원에게 커스텀 역할, 모니터링 뷰어 역할(roles/monitoring.viewer), 태그 뷰어 역할 (roles/resourcemanager.tagViewer)을 부여합니다.
각 팀에 대해 팀의 태그 값을 기반으로 하는 조건부 바인딩으로 태그 사용자 역할 (roles/resourcemanager.tagUser)과 모니터링 편집자 역할 (roles/monitoring.editor)을 부여합니다.
액세스를 제한할 알림 정책 또는 대시보드를 만듭니다. 자세한 내용은 Terraform을 사용하여 대시보드 만들기 및 Terraform을 사용하여 알림 정책 만들기를 참고하세요.
태그를 리소스에 바인딩합니다. Terraform을 사용하여 대시보드 또는 알림 정책에 태그를 연결하려면 google_tags_tag_binding를 사용하여 태그 바인딩 리소스를 만듭니다.

예를 들어 다음 Terraform 구성은 다음 작업을 실행합니다.

태그 키와 값을 만듭니다.
맞춤 역할을 만듭니다.
필수 역할과 조건부 권한을 부여하는 IAM 바인딩을 적용합니다.
대시보드를 만듭니다.
팀 소유권을 설정하기 위해 태그를 대시보드에 바인딩합니다.

동일한 명령어에서 리소스를 만들고 태그를 바인딩할 수는 없습니다. 리소스와 태그 바인딩을 별도로 만들어야 합니다.

# Create the tag key.
resource "google_tags_tag_key" "res_tag_key" {
  parent      = "projects/PROJECT_ID"
  short_name  = "owner"
  description = "Identifies the team that owns the resource"
}

# Create the tag value.
# Note: You must create a tag value resource for each team.
resource "google_tags_tag_value" "team_a_value" {
  parent      = "tagKeys/${google_tags_tag_key.res_tag_key.name}"
  short_name  = "team_a"
  description = "Team A ownership tag value"
}

# Create the custom Creator role.
resource "google_project_iam_custom_role" "creator_role" {
  role_id     = "dashboardAndPolicyCreator"
  title       = "Dashboard and Alerting Policy Creator"
  permissions = [
    "monitoring.alertPolicies.create",
    "monitoring.alertPolicies.createTagBinding",
    "monitoring.dashboards.create",
    "monitoring.dashboards.createTagBinding",
    "resourcemanager.tagValueBindings.create"
  ]
}

# Grant the Custom Creator role to all members.
resource "google_project_iam_binding" "creator_grant" {
  project = "PROJECT_ID"
  role    = join("/", [
    "projects",
    "PROJECT_ID",
    "roles",
    google_project_iam_custom_role.creator_role.role_id
  ])
  members = ["group:ALL_MEMBERS_GROUP_EMAIL"]
}

# Grant the Monitoring Viewer role to all members.
resource "google_project_iam_binding" "viewer_grant" {
  project = "PROJECT_ID"
  role    = "roles/monitoring.viewer"
  members = ["group:ALL_MEMBERS_GROUP_EMAIL"]
}

# Grant the Tag Viewer role to all members.
resource "google_project_iam_binding" "tag_viewer_grant" {
  project = "PROJECT_ID"
  role    = "roles/resourcemanager.tagViewer"
  members = ["group:ALL_MEMBERS_GROUP_EMAIL"]
}

# Grant the Tag User role with a condition.
# Note: You have to configure this team-specific binding for each team.
resource "google_project_iam_binding" "tag_user_grant" {
  project = "PROJECT_ID"
  role    = "roles/resourcemanager.tagUser"
  members = ["group:TEAM_A_GROUP_EMAIL"]

  condition {
    title       = "restrict_to_team_a"
    description = "Allow Tag User only for team_a tag"
    expression  = join("", [
      "resource.matchTagId('",
      google_tags_tag_key.res_tag_key.name,
      "', '",
      google_tags_tag_value.team_a_value.id,
      "')"
    ])
  }
}

# Grant the Monitoring Editor role with a condition.
# Note: You have to configure this team-specific binding for each team.
resource "google_project_iam_binding" "editor_grant" {
  project = "PROJECT_ID"
  role    = "roles/monitoring.editor"
  members = ["group:TEAM_A_GROUP_EMAIL"]

  condition {
    title       = "restrict_to_team_a"
    description = "Allow Monitoring Editor only for team_a tag"
    expression  = join("", [
      "resource.matchTagId('",
      google_tags_tag_key.res_tag_key.name,
      "', '",
      google_tags_tag_value.team_a_value.id,
      "')"
    ])
  }
}

# Create the dashboard.
resource "google_monitoring_dashboard" "example_dashboard" {
  dashboard_json = jsonencode({
    "displayName": "System Health Overview",
    "gridLayout": { "columns": "2", "widgets": [] }
  })
}

# Apply the tag binding to the dashboard to give team A ownership.
resource "google_tags_tag_binding" "dashboard_tag" {
  parent    = join("", [
    "//monitoring.googleapis.com/",
    google_monitoring_dashboard.example_dashboard.id
  ])
  tag_value = google_tags_tag_value.team_a_value.id
}

대시보드 및 알림 정책의 태그 관리

Google Cloud 콘솔 또는 gcloud CLI를 사용하여 대시보드 및 알림 정책에 태그를 연결하고, 나열하고, 삭제할 수 있습니다.

시작하기 전에

Cloud Monitoring 리소스의 태그를 관리하는 데 필요한 권한을 얻으려면 관리자에게 프로젝트 또는 조직에 대해 다음 IAM 역할을 부여해 달라고 요청하세요.

모니터링 뷰어 (roles/monitoring.viewer)
태그 뷰어 (roles/resourcemanager.tagViewer)
필요한 태그 작업과 해당 작업에 필요한 리소스 유형에 필요한 최소 권한이 있는 커스텀 역할 자세한 내용은 필수 권한 섹션을 펼치세요.

맞춤 역할을 설정할 때 각 태그 작업에 필요한 권한을 확인하려면 필수 권한 섹션을 펼치세요.

필수 권한

나열된 각 태그 작업에는 다음 권한이 필요합니다.

대시보드에 태그를 연결합니다.
- resourcemanager.tagValueBindings.create
- monitoring.dashboards.createTagBinding
알림 정책에 태그를 연결합니다.
- resourcemanager.tagValueBindings.create
- monitoring.alertPolicies.createTagBinding
대시보드에서 태그를 삭제합니다.
- resourcemanager.tagValueBindings.delete
- monitoring.dashboards.deleteTagBinding
알림 정책에서 태그를 삭제합니다.
- resourcemanager.tagValueBindings.delete
- monitoring.alertPolicies.deleteTagBinding

태그 연결

태그를 대시보드 또는 알림 정책에 연결하려면 다음을 수행합니다.

Google Cloud 콘솔

태그를 연결할 리소스 유형을 선택합니다.

대시보드

Google Cloud 콘솔에서 대시보드 페이지로 이동합니다.
대시보드로 이동

검색창을 사용하여 이 페이지를 찾은 경우 부제목이 Monitoring인 결과를 선택합니다.
태그를 연결할 대시보드를 선택합니다.
태그를 클릭합니다.
대화상자의 직접 태그 섹션에서 태그가 생성된 조직 또는 프로젝트를 선택하여 태그를 찾습니다. 예를 들어 프로젝트 수준에서 생성된 태그를 사용하려면 범위로 현재 프로젝트 선택을 선택합니다.

수동 입력 옵션을 선택하여 프로젝트, 조직 또는 태그 ID를 수동으로 검색할 수도 있습니다.
적절한 키-값 쌍을 선택한 후 저장을 클릭합니다.
변경사항을 확인하는 대화상자가 표시됩니다. 확인을 클릭하여 변경사항을 완료합니다.

알림 정책

Google Cloud 콘솔에서 정책 페이지로 이동합니다.
알림 정책으로 이동

검색창을 사용하여 이 페이지를 찾은 경우 부제목이 Monitoring인 결과를 선택합니다.
태그를 연결할 알림 정책을 선택합니다.
태그를 클릭합니다.
대화상자의 직접 태그 섹션에서 태그가 생성된 조직 또는 프로젝트를 선택하여 태그를 찾습니다. 예를 들어 프로젝트 수준에서 생성된 태그를 사용하려면 범위로 현재 프로젝트 선택을 선택합니다.

수동 입력 옵션을 선택하여 프로젝트, 조직 또는 태그 ID를 수동으로 검색할 수도 있습니다.
적절한 키-값 쌍을 선택한 후 저장을 클릭합니다.
변경사항을 확인하는 대화상자가 표시됩니다. 확인을 클릭하여 변경사항을 완료합니다.

gcloud

아래의 명령어 데이터를 사용하기 전에 다음을 바꿉니다.

TAG_VALUE_ID: 태그 값의 영구 ID 또는 네임스페이스화된 이름입니다. 예를 들면 tagValues/4567890123입니다. 태그 식별자에 대한 자세한 내용은 태그 정의 및 식별자를 참고하세요.
PARENT: 상위 리소스의 정규화된 이름입니다. 예를 들어 //monitoring.googleapis.com/projects/PROJECT_ID_OR_NUMBER/dashboards/DASHBOARD_ID 또는 //monitoring.googleapis.com/projects/PROJECT_ID_OR_NUMBER/alertPolicies/POLICY_ID입니다.

resource-manager tags bindings create 명령어를 실행합니다.

Linux, macOS 또는 Cloud Shell

gcloud resource-manager tags bindings create \
    --tag-value=TAG_VALUE_ID \
    --parent=PARENT

Windows(PowerShell)

gcloud resource-manager tags bindings create `
    --tag-value=TAG_VALUE_ID `
    --parent=PARENT

Windows(cmd.exe)

gcloud resource-manager tags bindings create ^
    --tag-value=TAG_VALUE_ID ^
    --parent=PARENT

다음과 비슷한 응답이 표시됩니다.

'@type': type.googleapis.com/google.cloud.resourcemanager.v3.TagBinding
name: tagBindings/%2F%2Fmonitoring.googleapis.com%2Fprojects%2F1234567890%2FalertPolicies%2F0987654321/tagValues/1029384756
parent: //monitoring.googleapis.com/projects/1234567890/alertPolicies/0987654321
tagValue: tagValues/1029384756
tagValueNamespacedName: my-project/owner/team_a

태그 보기

대시보드 또는 알림 정책에 연결된 태그를 보려면 다음을 수행합니다.

Google Cloud 콘솔

태그를 보려는 리소스 유형을 선택합니다.

대시보드

Google Cloud 콘솔에서 대시보드 페이지로 이동합니다.
대시보드로 이동

검색창을 사용하여 이 페이지를 찾은 경우 부제목이 Monitoring인 결과를 선택합니다.
태그를 보려는 대시보드를 선택합니다.
태그를 클릭합니다. 첨부된 모든 태그가 나열된 대화상자가 열립니다.

알림 정책

Google Cloud 콘솔에서 정책 페이지로 이동합니다.
알림 정책으로 이동

검색창을 사용하여 이 페이지를 찾은 경우 부제목이 Monitoring인 결과를 선택합니다.
태그를 보려는 알림 정책을 선택합니다.
태그를 클릭합니다. 첨부된 모든 태그가 나열된 대화상자가 열립니다.

gcloud

아래의 명령어 데이터를 사용하기 전에 다음을 바꿉니다.

PARENT: 상위 리소스의 정규화된 이름입니다. 예를 들어 //monitoring.googleapis.com/projects/PROJECT_ID_OR_NUMBER/dashboards/DASHBOARD_ID 또는 //monitoring.googleapis.com/projects/PROJECT_ID_OR_NUMBER/alertPolicies/POLICY_ID입니다.

resource-manager tags bindings list 명령어를 실행합니다.

Linux, macOS 또는 Cloud Shell

gcloud resource-manager tags bindings list \
    --parent=PARENT

Windows(PowerShell)

gcloud resource-manager tags bindings list `
    --parent=PARENT

Windows(cmd.exe)

gcloud resource-manager tags bindings list ^
    --parent=PARENT

리소스에서 상속된 태그를 보려면 --effective 플래그를 추가합니다. 이 플래그를 추가하면 다음과 유사한 응답이 반환됩니다.

  namespacedTagKey: my-project/owner
  namespacedTagValue: my-project/owner/team_a
  tagKey: tagKeys/5647382910
  tagValue: tagValues/1029384756
  inherited: true

모든 태그가 리소스에 명시적으로 연결되고 상속된 태그가 없으면 inherited 필드는 생략됩니다.

리소스에서 태그 삭제

대시보드 또는 알림 정책에 연결된 태그를 삭제하려면 태그 바인딩을 삭제해야 합니다. 리소스에서 태그를 삭제해도 태그가 삭제되지는 않습니다. 태그 삭제 방법은 태그 삭제를 참고하세요.

Google Cloud 콘솔

태그를 삭제할 리소스 유형을 선택합니다.

대시보드

Google Cloud 콘솔에서 대시보드 페이지로 이동합니다.
대시보드로 이동

검색창을 사용하여 이 페이지를 찾은 경우 부제목이 Monitoring인 결과를 선택합니다.
태그를 삭제할 대시보드를 선택합니다.
태그를 클릭합니다.
대화상자에서 삭제할 태그 위로 포인터를 가져가고 항목 삭제를 클릭합니다. 저장을 클릭하여 변경사항을 저장합니다.
변경사항을 확인하는 대화상자가 표시됩니다. 확인을 클릭하여 변경사항을 완료합니다.

알림 정책

Google Cloud 콘솔에서 정책 페이지로 이동합니다.
알림 정책으로 이동

검색창을 사용하여 이 페이지를 찾은 경우 부제목이 Monitoring인 결과를 선택합니다.
태그를 삭제할 알림 정책을 선택합니다.
태그를 클릭합니다.
대화상자에서 삭제할 태그 위로 포인터를 가져가고 항목 삭제를 클릭합니다. 저장을 클릭하여 변경사항을 저장합니다.
변경사항을 확인하는 대화상자가 표시됩니다. 확인을 클릭하여 변경사항을 완료합니다.

gcloud

아래의 명령어 데이터를 사용하기 전에 다음을 바꿉니다.

TAG_VALUE_ID: 태그 값의 영구 ID 또는 네임스페이스화된 이름입니다. 예를 들면 tagValues/4567890123입니다. 태그 식별자에 대한 자세한 내용은 태그 정의 및 식별자를 참고하세요.
PARENT: 상위 리소스의 정규화된 이름입니다. 예를 들어 //monitoring.googleapis.com/projects/PROJECT_ID_OR_NUMBER/dashboards/DASHBOARD_ID 또는 //monitoring.googleapis.com/projects/PROJECT_ID_OR_NUMBER/alertPolicies/POLICY_ID입니다.

resource-manager tags bindings delete 명령어를 실행합니다.

Linux, macOS 또는 Cloud Shell

gcloud resource-manager tags bindings delete \
    --tag-value=TAG_VALUE_ID \
    --parent=PARENT

Windows(PowerShell)

gcloud resource-manager tags bindings delete `
    --tag-value=TAG_VALUE_ID `
    --parent=PARENT

Windows(cmd.exe)

gcloud resource-manager tags bindings delete ^
    --tag-value=TAG_VALUE_ID ^
    --parent=PARENT

응답이 비어 있습니다.

제한사항

연결된 태그를 기준으로 대시보드 또는 알림 정책을 필터링할 수는 없습니다. 특정 태그가 연결된 리소스를 나열하려면 태그와 함께 라벨을 연결하고 라벨을 기준으로 필터링하는 것이 좋습니다. 라벨 추가에 대한 자세한 내용은 라벨로 알림에 주석 추가 및 대시보드에 라벨 추가 또는 삭제를 참고하세요.

태그를 사용하여 리소스 액세스 제어 컬렉션을 사용해 정리하기 내 환경설정을 기준으로 콘텐츠를 저장하고 분류하세요.

액세스 제어 패턴

Terraform 관리 리소스 보호

시작하기 전에

거부 정책을 사용하여 리소스 보호

Google Cloud 콘솔

Terraform

팀 범위 액세스 구성

시작하기 전에

팀별 태그 적용

Google Cloud 콘솔

Terraform

대시보드 및 알림 정책의 태그 관리

시작하기 전에

필수 권한

태그 연결

Google Cloud 콘솔

대시보드

알림 정책

gcloud

Linux, macOS 또는 Cloud Shell

Windows(PowerShell)

Windows(cmd.exe)

태그 보기

Google Cloud 콘솔

대시보드

알림 정책

gcloud

Linux, macOS 또는 Cloud Shell

Windows(PowerShell)

Windows(cmd.exe)

리소스에서 태그 삭제

Google Cloud 콘솔

대시보드

알림 정책

gcloud

Linux, macOS 또는 Cloud Shell

Windows(PowerShell)

Windows(cmd.exe)

제한사항

태그를 사용하여 리소스 액세스 제어