Tutoriel sur Pub/Sub pour Terraform

Ce tutoriel explique comment déployer une fonction Pub/Sub en important un fichier ZIP de code source de fonction dans un bucket Cloud Storage, à l'aide de Terraform pour provisionner les ressources. Terraform est un outil Open Source qui vous permet de provisionner des ressources Google Cloud à l'aide de fichiers de configuration déclaratifs.

Ce tutoriel utilise une fonction Node.js comme exemple, mais il fonctionne également avec les fonctions Python, Go et Java. Les instructions sont identiques, quel que soit l'environnement d'exécution que vous utilisez. Pour en savoir plus sur l'utilisation de Terraform avec l'API Cloud Functions v2, consultez les pages de référence de Hashicorp.

Configurer votre environnement

Dans ce tutoriel, vous exécutez des commandes dans Cloud Shell. Cloud Shell est un environnement de shell dans lequel la Google Cloud CLI est déjà installée avec des valeurs prédéfinies pour votre projet actuel. L'initialisation de Cloud Shell peut prendre quelques minutes.

Ouvrir Cloud Shell

Préparer l'application

Dans Cloud Shell, procédez comme suit :

1. Clonez le dépôt de l'exemple d'application sur votre instance Cloud Shell :

   git clone https://github.com/terraform-google-modules/terraform-docs-samples.git

2. Accédez au répertoire contenant l'exemple de code de Cloud Run Functions :

   cd terraform-docs-samples/functions/pubsub

   L'exemple Node.js utilisé dans ce tutoriel est une fonction Pub/Sub de base "Hello World". Voici le fichier main.tf :

   terraform {
     required_providers {
       google = {
         source  = "hashicorp/google"
         version = ">= 4.34.0"
       }
     }
   }
   
   resource "random_id" "bucket_prefix" {
     byte_length = 8
   }
   
   
   resource "google_service_account" "default" {
     account_id   = "test-gcf-sa"
     display_name = "Test Service Account"
   }
   
   resource "google_pubsub_topic" "default" {
     name = "functions2-topic"
   }
   
   resource "google_storage_bucket" "default" {
     name                        = "${random_id.bucket_prefix.hex}-gcf-source" # Every bucket name must be globally unique
     location                    = "US"
     uniform_bucket_level_access = true
   }
   
   data "archive_file" "default" {
     type        = "zip"
     output_path = "/tmp/function-source.zip"
     source_dir  = "function-source/"
   }
   
   resource "google_storage_bucket_object" "default" {
     name   = "function-source.zip"
     bucket = google_storage_bucket.default.name
     source = data.archive_file.default.output_path # Path to the zipped function source code
   }
   
   resource "google_cloudfunctions2_function" "default" {
     name        = "function"
     location    = "us-central1"
     description = "a new function"
   
     build_config {
       runtime     = "nodejs22"
       entry_point = "helloPubSub" # Set the entry point
       environment_variables = {
         BUILD_CONFIG_TEST = "build_test"
       }
       source {
         storage_source {
           bucket = google_storage_bucket.default.name
           object = google_storage_bucket_object.default.name
         }
       }
     }
   
     service_config {
       max_instance_count = 3
       min_instance_count = 1
       available_memory   = "256M"
       timeout_seconds    = 60
       environment_variables = {
         SERVICE_CONFIG_TEST = "config_test"
       }
       ingress_settings               = "ALLOW_INTERNAL_ONLY"
       all_traffic_on_latest_revision = true
       service_account_email          = google_service_account.default.email
     }
   
     event_trigger {
       trigger_region = "us-central1"
       event_type     = "google.cloud.pubsub.topic.v1.messagePublished"
       pubsub_topic   = google_pubsub_topic.default.id
       retry_policy   = "RETRY_POLICY_RETRY"
     }
   }

Initialiser Terraform

Dans le répertoire terraform-docs-samples/functions/pubsub contenant le fichier main.tf, exécutez cette commande pour ajouter les plug-ins nécessaires et créez le répertoire .terraform :

terraform init

Valider la configuration Terraform

Prévisualisez la configuration Terraform. Bien que facultative, cette étape vous permet de vérifier que la syntaxe de main.tf est correcte. Cette commande affiche un aperçu des ressources qui seront créées :

terraform plan

Appliquer la configuration Terraform

Déployez la fonction en appliquant la configuration. Lorsque vous y êtes invité, saisissez yes.

terraform apply

Déclencher la fonction

Pour tester la fonction Pub/Sub, procédez comme suit :

1. Publiez un message sur le sujet (dans cet exemple, le nom du sujet est functions2-topic) :

   gcloud pubsub topics publish TOPIC_NAME --message="Friend"

2. Lisez les journaux de la fonction pour afficher le résultat, où FUNCTION_NAME correspond au nom de la fonction (dans cet exemple, le nom de la fonction est function) :

   gcloud functions logs read FUNCTION_NAME

   Les résultats de journalisation incluant votre nouveau message "Ami" doivent s'afficher.

   Remarque : L'apparition des journaux peut prendre quelques instants. Si vous ne les voyez pas immédiatement, patientez une à deux minutes et vérifiez à nouveau.

Effectuer un nettoyage

Une fois le tutoriel terminé, vous pouvez supprimer tous les éléments que vous avez créés afin d'éviter tous frais supplémentaires.

Terraform vous permet de supprimer toutes les ressources définies dans le fichier de configuration en exécutant la commande terraform destroy :

terraform destroy

Saisissez yes pour autoriser Terraform à supprimer vos ressources.