Solicitar um certificado usando um modelo de certificado

Esta página descreve como solicitar um certificado usando um modelo de certificado.

Os modelos de certificado permitem implementar controles de política refinados na emissão de certificados. Por exemplo, é possível usar modelos de certificado para padronizar a emissão de certificados TLS do servidor em pools de ACs na sua organização. Ou, você pode usar modelos de certificado para aplicar políticas em um nível mais granular, como para usuários específicos. Isso é útil em situações em que é necessário restringir os tipos de certificados que diferentes pessoas podem emitir. Também é possível reutilizar modelos para cenários de emissão comuns.

Antes de começar

  1. Prepare seu ambiente para o serviço de AC.

  2. Para receber as permissões necessárias para emitir certificados usando um modelo de certificado, peça ao administrador para conceder a você o papel do IAM de usuário do modelo de certificado do serviço de AC (roles/privateca.templateUser) no modelo de certificado.

    Para mais informações sobre os papéis predefinidos do IAM para o serviço de AC, consulte Controle de acesso com o IAM.

    Para informações sobre como conceder um papel do IAM a um principal, consulte Conceder um único papel.

Emissão de certificado de teste

Antes de usar um modelo de certificado para solicitar um certificado assinado, recomendamos que você verifique a capacidade do modelo de certificado de gerar um certificado. A emissão de certificado falha quando há um conflito entre as políticas de emissão do pool de ACs e as políticas do modelo de certificado. Ao testar a emissão, você pode identificar e resolver esses conflitos de maneira proativa. Os certificados de teste não são codificados em PEM, não são assinados e não geram cobranças.

Para testar a emissão de certificados usando um modelo de certificado, siga estas etapas:

Console

  1. Acesse a página Certificate Authority Service no Google Cloud console.

    Acesse Certificate Authority Service

  2. Clique na guia Gerenciador de modelos.

  3. Clique no modelo de certificado que você quer testar. A página Detalhes do modelo aparece.

  4. Para criar uma solicitação de teste, clique em Criar certificado e em Testar emissão de certificado. O formulário de solicitação de certificado aparece.

  5. Especifique os detalhes necessários para criar uma solicitação de certificado:

    • Região: local do certificado. Precisa ser igual ao local do pool de ACs.
    • Pool de ACs: o pool de ACs responsável pela emissão do certificado.
    • Modelo de certificado: o modelo que você quer usar para a emissão de certificados.
    • Domínio: o nome de domínio do site que você quer proteger com um certificado SSL ou TLS.

  6. Clique em Gerar certificado.

  7. Depois que o certificado for criado, clique em Visualizar. O certificado de teste ou de amostra é exibido na mesma página em um painel separado.

  8. Se a emissão de certificado falhar devido a conflitos, resolva os conflitos e envie a solicitação de certificado de teste novamente.

Emitir certificados usando um modelo de certificado

Para emitir um certificado assinado usando um modelo de certificado, faça o seguinte:

Console

  1. Acesse a página Certificate Authority Service no Google Cloud console.

    Acesse Certificate Authority Service}

  2. Clique na guia Gerenciador de modelos.

  3. Na página Modelos de certificado, clique no modelo de certificado que você quer usar. A página Detalhes do modelo aparece.

  4. Clique em Criar certificado.

  5. Selecione uma região. Essa região precisa ser a mesma do pool de ACs que você pretende usar.

  6. Selecione o pool de ACs.

  7. Para gerar um certificado usando uma solicitação de assinatura de certificado (CSR), consulte Solicitar um certificado usando a CSR.

  8. Para gerar um certificado usando uma chave gerada automaticamente, consulte Solicitar certificado usando uma chave gerada automaticamente.

Gerar o certificado

  1. Clique em Gerar certificado. Se o certificado for gerado, uma mensagem será exibida.
  2. Para conferir o certificado gerado, clique em Visualizar certificado e em Visualizar.

Opcional: fazer o download do certificado assinado

  1. Para fazer o download da cadeia de certificados codificada em PEM, clique em Fazer o download da cadeia de certificados.
  2. Para fazer o download da chave privada codificada em PEM associada, clique em Fazer o download da chave privada.

gcloud

Para emitir um certificado usando um modelo de certificado, adicione a flag --template ao comando gcloud privateca certificates create no seguinte formato:

--template=projects/PROJECT_ID/locations/LOCATION/certificateTemplates/CERTIFICATE_TEMPLATE

Substitua CERTIFICATE_TEMPLATE pelo nome do modelo de certificado que você quer usar para emitir esse certificado. O modelo especificado precisa estar no mesmo local que o pool de ACs emissor. Consulte os exemplos fornecidos para gerar certificados DNS de teste e gerar certificados de produção para mais informações.

Terraform

/**
 * Copyright 2022 Google LLC
 *
 * Licensed under the Apache License, Version 2.0 (the "License");
 * you may not use this file except in compliance with the License.
 * You may obtain a copy of the License at
 *
 *      http://www.apache.org/licenses/LICENSE-2.0
 *
 * Unless required by applicable law or agreed to in writing, software
 * distributed under the License is distributed on an "AS IS" BASIS,
 * WITHOUT WARRANTIES OR CONDITIONS OF ANY KIND, either express or implied.
 * See the License for the specific language governing permissions and
 * limitations under the License.
 */

resource "google_privateca_certificate_template" "template" {
  location    = "us-central1"
  name        = "my-certificate-template"
  description = "An updated sample certificate template"

  identity_constraints {
    allow_subject_alt_names_passthrough = true
    allow_subject_passthrough           = true

    cel_expression {
      description = "Always true"
      expression  = "true"
      location    = "any.file.anywhere"
      title       = "Sample expression"
    }
  }

  passthrough_extensions {
    additional_extensions {
      object_id_path = [1, 6]
    }

    known_extensions = ["EXTENDED_KEY_USAGE"]
  }

  predefined_values {
    additional_extensions {
      object_id {
        object_id_path = [1, 6]
      }

      value    = "c3RyaW5nCg=="
      critical = true
    }

    aia_ocsp_servers = ["string"]

    ca_options {
      is_ca                  = false
      max_issuer_path_length = 6
    }

    key_usage {
      base_key_usage {
        cert_sign          = false
        content_commitment = true
        crl_sign           = false
        data_encipherment  = true
        decipher_only      = true
        digital_signature  = true
        encipher_only      = true
        key_agreement      = true
        key_encipherment   = true
      }

      extended_key_usage {
        client_auth      = true
        code_signing     = true
        email_protection = true
        ocsp_signing     = true
        server_auth      = true
        time_stamping    = true
      }

      unknown_extended_key_usages {
        object_id_path = [1, 6]
      }
    }

    policy_ids {
      object_id_path = [1, 6]
    }
  }
}

resource "google_privateca_certificate_authority" "test_ca" {
  pool                     = "my-pool"
  certificate_authority_id = "my-certificate-authority-test-ca"
  location                 = "us-central1"
  deletion_protection      = false # set to true to prevent destruction of the resource
  config {
    subject_config {
      subject {
        organization = "HashiCorp"
        common_name  = "my-certificate-authority"
      }
      subject_alt_name {
        dns_names = ["hashicorp.com"]
      }
    }
    x509_config {
      ca_options {
        # is_ca *MUST* be true for certificate authorities
        is_ca = true
      }
      key_usage {
        base_key_usage {
          # cert_sign and crl_sign *MUST* be true for certificate authorities
          cert_sign = true
          crl_sign  = true
        }
        extended_key_usage {
          server_auth = false
        }
      }
    }
  }
  key_spec {
    algorithm = "RSA_PKCS1_4096_SHA256"
  }
}


resource "google_privateca_certificate" "default" {
  pool                  = "my-pool"
  location              = "us-central1"
  certificate_authority = google_privateca_certificate_authority.test_ca.certificate_authority_id
  lifetime              = "860s"
  name                  = "my-certificate-from-template"
  pem_csr               = tls_cert_request.example.cert_request_pem
  certificate_template  = google_privateca_certificate_template.template.id
}

resource "tls_private_key" "example" {
  algorithm = "RSA"
}

resource "tls_cert_request" "example" {
  private_key_pem = tls_private_key.example.private_key_pem

  subject {
    common_name  = "example.com"
    organization = "ACME Examples, Inc"
  }
}

Para saber como aplicar ou remover uma configuração do Terraform, consulte Comandos básicos do Terraform.

Uma solicitação de certificado poderá falhar se um conflito de política for detectado entre a política de emissão do pool de ACs e o modelo de certificado. Quando isso acontece, é necessário resolver o conflito de política antes de enviar a solicitação de certificado novamente.

Para compartilhar um link de formulário de solicitação de certificado com outras pessoas na sua organização para que elas possam solicitar um certificado usando os mesmos parâmetros, faça o seguinte:

Console

  1. No Google Cloud console, acesse a guia Gerenciador de pools de ACs e clique em Compartilhar link do formulário de solicitação.
  2. No painel Compartilhar link do formulário de solicitação que aparece, selecione o pool de ACs e o modelo de certificado que você escolheu para criar sua solicitação. O link de solicitação de certificado é exibido.
  3. Copie o link e compartilhe conforme necessário.

Ver certificados emitidos usando um modelo

Para conferir os certificados emitidos usando um modelo de certificado, faça o seguinte:

Console

  1. No Google Cloud console, acesse a guia Gerenciador de modelos.
  2. Clique no modelo de certificado que você usou para a emissão de certificados.
  3. Na página Detalhes do modelo, clique em Certificados. A lista de certificados emitidos usando o modelo de certificado selecionado é exibida.

A seguir