Demander un certificat à l'aide d'un modèle de certificat

Cette page explique comment demander un certificat à l'aide d'un modèle de certificat.

Les modèles de certificat vous permettent d'implémenter des contrôles de règles précis sur l'émission de vos certificats. Par exemple, vous pouvez utiliser des modèles de certificat pour standardiser l'émission de certificats TLS de serveur dans les pools d'autorités de certification de votre organisation. Vous pouvez également utiliser des modèles de certificat pour appliquer des règles à un niveau plus précis, par exemple à des utilisateurs spécifiques. Cela est utile lorsque vous devez limiter les types de certificats que différentes personnes peuvent émettre. Vous pouvez également réutiliser des modèles pour des scénarios d'émission courants.

Avant de commencer

  1. Préparez votre environnement pour CA Service.

  2. Pour obtenir les autorisations nécessaires pour émettre des certificats à l'aide d'un modèle de certificat, demandez à votre administrateur de vous accorder le rôle IAM Utilisateur de modèle de certificat CA Service (roles/privateca.templateUser) sur le modèle de certificat.

    Pour en savoir plus sur les rôles IAM prédéfinis pour CA Service, consultez la page Contrôle des accès avec IAM.

    Pour savoir comment accorder un rôle IAM à un principal, consultez la section Accorder un seul rôle.

Émission de certificats de test

Avant d'utiliser un modèle de certificat pour demander un certificat signé, nous vous recommandons de vérifier que le modèle de certificat est en mesure de générer un certificat. L'émission de certificats échoue en cas de conflit entre les règles d'émission du pool d'autorités de certification et les règles du modèle de certificat. En testant l'émission, vous pouvez identifier et résoudre ces conflits de manière proactive. Notez que les certificats de test ne sont pas encodés au format PEM, qu'ils ne sont pas signés et qu'ils n'entraînent aucun frais de génération.

Pour tester l'émission de certificats à l'aide d'un modèle de certificat, procédez comme suit :

Console

  1. Accédez à la page Certificate Authority Service (Service d'autorité de certification) dans la Google Cloud console.

    Accéder à Certificate Authority Service

  2. Cliquez sur l'onglet Template Manager (Gestionnaire de modèles).

  3. Cliquez sur le modèle de certificat que vous souhaitez tester. La page Template Details (Détails du modèle) s'affiche.

  4. Pour créer une demande de test, cliquez sur Create certificate (Créer un certificat), puis sur Test certificate issuance (Tester l'émission de certificats). Le formulaire de demande de certificat s'affiche.

  5. Spécifiez les informations suivantes requises pour créer une demande de certificat :

    • Region (Région) : emplacement du certificat. Il doit être identique à l'emplacement du pool d'autorités de certification.
    • CA pool (Pool d'autorités de certification) : pool d'autorités de certification responsable de l'émission du certificat.
    • Certificate template (Modèle de certificat) : modèle que vous souhaitez utiliser pour l'émission de certificats.
    • Domain (Domaine) : nom de domaine du site que vous souhaitez sécuriser à l'aide d'un certificat SSL ou TLS.

  6. Cliquez sur Generate certificate (Générer un certificat).

  7. Une fois le certificat créé, cliquez sur View (Afficher). Le certificat de test ou d'exemple s'affiche sur la même page dans un panneau distinct.

  8. Si l'émission de certificats échoue en raison de conflits, résolvez-les, puis envoyez à nouveau la demande de certificat de test.

Émettre des certificats à l'aide d'un modèle de certificat

Pour émettre un certificat signé à l'aide d'un modèle de certificat, procédez comme suit :

Console

  1. Accédez à la page Certificate Authority Service (Service d'autorité de certification) dans la Google Cloud console.

    Accéder à Certificate Authority Service}

  2. Cliquez sur l'onglet Template Manager (Gestionnaire de modèles).

  3. Sur la page Certificate templates (Modèles de certificat), cliquez sur le modèle de certificat que vous souhaitez utiliser. La page Template details (Détails du modèle) s'affiche.

  4. Cliquez sur Create certificate (Créer un certificat).

  5. Sélectionnez une région. Cette région doit être identique à celle du pool d'autorités de certification que vous comptez utiliser.

  6. Sélectionnez le pool d'autorités de certification.

  7. Pour générer un certificat à l'aide d'une demande de signature de certificat (CSR), consultez Demander un certificat à l'aide d'une CSR.

  8. Pour générer un certificat à l'aide d'une clé générée automatiquement, consultez Demander un certificat à l'aide d'une clé générée automatiquement.

Générer le certificat

  1. Cliquez sur Generate certificate (Générer un certificat). Si le certificat est généré, un message s'affiche.
  2. Pour afficher le certificat généré, cliquez sur View certificate, puis cliquez sur View.

Facultatif : Télécharger le certificat signé

  1. Pour télécharger la chaîne de certificats encodée au format PEM, cliquez sur Download certificate chain (Télécharger la chaîne de certificats).
  2. Pour télécharger la clé privée encodée au format PEM associée, cliquez sur Download private key (Télécharger la clé privée).

gcloud

Pour émettre un certificat à l'aide d'un modèle de certificat, ajoutez l'option --template à la commande gcloud privateca certificates create au format suivant :

--template=projects/PROJECT_ID/locations/LOCATION/certificateTemplates/CERTIFICATE_TEMPLATE

Remplacez CERTIFICATE_TEMPLATE par le nom du modèle de certificat que vous souhaitez utiliser pour émettre ce certificat. Le modèle spécifié doit se trouver au même emplacement que le pool d'autorités de certification émetteur. Pour en savoir plus, consultez les exemples fournis pour générer des certificats DNS de test et générer des certificats de production.

Terraform

/**
 * Copyright 2022 Google LLC
 *
 * Licensed under the Apache License, Version 2.0 (the "License");
 * you may not use this file except in compliance with the License.
 * You may obtain a copy of the License at
 *
 *      http://www.apache.org/licenses/LICENSE-2.0
 *
 * Unless required by applicable law or agreed to in writing, software
 * distributed under the License is distributed on an "AS IS" BASIS,
 * WITHOUT WARRANTIES OR CONDITIONS OF ANY KIND, either express or implied.
 * See the License for the specific language governing permissions and
 * limitations under the License.
 */

resource "google_privateca_certificate_template" "template" {
  location    = "us-central1"
  name        = "my-certificate-template"
  description = "An updated sample certificate template"

  identity_constraints {
    allow_subject_alt_names_passthrough = true
    allow_subject_passthrough           = true

    cel_expression {
      description = "Always true"
      expression  = "true"
      location    = "any.file.anywhere"
      title       = "Sample expression"
    }
  }

  passthrough_extensions {
    additional_extensions {
      object_id_path = [1, 6]
    }

    known_extensions = ["EXTENDED_KEY_USAGE"]
  }

  predefined_values {
    additional_extensions {
      object_id {
        object_id_path = [1, 6]
      }

      value    = "c3RyaW5nCg=="
      critical = true
    }

    aia_ocsp_servers = ["string"]

    ca_options {
      is_ca                  = false
      max_issuer_path_length = 6
    }

    key_usage {
      base_key_usage {
        cert_sign          = false
        content_commitment = true
        crl_sign           = false
        data_encipherment  = true
        decipher_only      = true
        digital_signature  = true
        encipher_only      = true
        key_agreement      = true
        key_encipherment   = true
      }

      extended_key_usage {
        client_auth      = true
        code_signing     = true
        email_protection = true
        ocsp_signing     = true
        server_auth      = true
        time_stamping    = true
      }

      unknown_extended_key_usages {
        object_id_path = [1, 6]
      }
    }

    policy_ids {
      object_id_path = [1, 6]
    }
  }
}

resource "google_privateca_certificate_authority" "test_ca" {
  pool                     = "my-pool"
  certificate_authority_id = "my-certificate-authority-test-ca"
  location                 = "us-central1"
  deletion_protection      = false # set to true to prevent destruction of the resource
  config {
    subject_config {
      subject {
        organization = "HashiCorp"
        common_name  = "my-certificate-authority"
      }
      subject_alt_name {
        dns_names = ["hashicorp.com"]
      }
    }
    x509_config {
      ca_options {
        # is_ca *MUST* be true for certificate authorities
        is_ca = true
      }
      key_usage {
        base_key_usage {
          # cert_sign and crl_sign *MUST* be true for certificate authorities
          cert_sign = true
          crl_sign  = true
        }
        extended_key_usage {
          server_auth = false
        }
      }
    }
  }
  key_spec {
    algorithm = "RSA_PKCS1_4096_SHA256"
  }
}


resource "google_privateca_certificate" "default" {
  pool                  = "my-pool"
  location              = "us-central1"
  certificate_authority = google_privateca_certificate_authority.test_ca.certificate_authority_id
  lifetime              = "860s"
  name                  = "my-certificate-from-template"
  pem_csr               = tls_cert_request.example.cert_request_pem
  certificate_template  = google_privateca_certificate_template.template.id
}

resource "tls_private_key" "example" {
  algorithm = "RSA"
}

resource "tls_cert_request" "example" {
  private_key_pem = tls_private_key.example.private_key_pem

  subject {
    common_name  = "example.com"
    organization = "ACME Examples, Inc"
  }
}

Pour savoir comment appliquer ou supprimer une configuration Terraform, consultez la page Commandes Terraform de base.

Une demande de certificat peut échouer si un conflit de règles est détecté entre la règle d'émission du pool d'autorités de certification et le modèle de certificat. Dans ce cas, vous devez résoudre le conflit de règles avant de pouvoir envoyer à nouveau la demande de certificat.

Pour partager un lien de formulaire de demande de certificat avec d'autres membres de votre organisation afin qu'ils puissent demander un certificat à l'aide des mêmes paramètres, procédez comme suit :

Console

  1. Dans la Google Cloud console, accédez à l'onglet CA pool manager (Gestionnaire de pools d'autorités de certification), puis cliquez sur Share request form link (Partager le lien du formulaire de demande).
  2. Dans le panneau Share request form link (Partager le lien du formulaire de demande) qui s'affiche, sélectionnez le pool d'autorités de certification et le modèle de certificat que vous avez choisis pour créer votre demande. Le lien de demande de certificat s'affiche.
  3. Copiez le lien et partagez-le si nécessaire.

Afficher les certificats émis à l'aide d'un modèle

Pour afficher les certificats émis à l'aide d'un modèle de certificat, procédez comme suit :

Console

  1. Dans la Google Cloud console, accédez à l'onglet Template Manager (Gestionnaire de modèles).
  2. Cliquez sur le modèle de certificat que vous avez utilisé pour l'émission de certificats.
  3. Sur la page Template Details (Détails du modèle), cliquez sur Certificates (Certificats). La liste des certificats émis à l'aide du modèle de certificat sélectionné s'affiche.

Étape suivante