Terraform-Anleitung

In dieser Anleitung wird gezeigt, wie Sie eine HTTP-Funktion bereitstellen. Dazu laden Sie eine ZIP-Datei mit dem Funktionsquellcode in einen Cloud Storage-Bucket hoch und verwenden Terraform zum Bereitstellen der Ressourcen. Terraform ist ein Open Source-Tool, mit dem Sie Ressourcen mit deklarativen Konfigurationsdateien bereitstellen können. Google Cloud

In dieser Anleitung wird als Beispiel eine HTTP-Funktion von Node.js verwendet. Sie funktioniert jedoch auch mit Python-, Go- und Java-HTTP-Funktionen. Die Anleitungen sind identisch, unabhängig davon, welche dieser Laufzeiten Sie verwenden.

Wenn Sie mit Terraform bereitstellen, müssen Sie die gezippte Quelldatei Ihrer Funktion in einen Cloud Storage-Bucket (source_archive_bucket), hochladen und auch den Cloud Storage-Objektnamen (source_archive_object) in der Terraform-Konfiguration angeben. Weitere Informationen finden Sie im Terraform-Spezifikationsleitfaden.

Cloud Run Functions kopiert die Quelldatei, die Sie in source_archive_bucket hochladen, in einen Bucket in Ihrem Projekt. Der Bucket-Name hat das Format gcf-v2-sources-PROJECT_NUMBER-REGION(Cloud Run Functions) oder gcf-sources-PROJECT_NUMBER-REGION Cloud Run Functions (1. Generation). Diese Konfiguration variiert je nach CMEK-Abhängigkeit.

Ziele

• Anleitung zum Bereitstellen einer HTTP-Funktion mit Terraform

Kosten

In diesem Dokument verwenden Sie die folgenden kostenpflichtigen Komponenten von Google Cloud:

• Cloud Run functions
• Cloud Build
• Cloud Storage
• Artifact Registry

For details, see Cloud Run functions pricing.

Mit dem Preisrechner können Sie eine Kostenschätzung für Ihre voraussichtliche Nutzung vornehmen. Verwenden Sie den Preisrechner.

Neuen Nutzern von Google Cloud steht möglicherweise eine kostenlose Testversion zur Verfügung.

Hinweis

Melden Sie sich in Ihrem Google Cloud Konto an. Wenn Sie mit Google Cloudnoch nicht vertraut sind, erstellen Sie ein Konto, um die Leistung unserer Produkte in der Praxis sehen und bewerten zu können. Neukunden erhalten außerdem ein Guthaben von 300 $, um Arbeitslasten auszuführen, zu testen und bereitzustellen.

In the Google Cloud console, on the project selector page, select or create a Google Cloud project.

Roles required to select or create a project

• Select a project: Selecting a project doesn't require a specific IAM role—you can select any project that you've been granted a role on.
• Create a project: To create a project, you need the Project Creator role (roles/resourcemanager.projectCreator), which contains the resourcemanager.projects.create permission. Learn how to grant roles.

Note: If you don't plan to keep the resources that you create in this procedure, create a project instead of selecting an existing project. After you finish these steps, you can delete the project, removing all resources associated with the project.

Go to project selector

Verify that billing is enabled for your Google Cloud project.

Enable the Cloud Functions, Cloud Run, Cloud Build, Artifact Registry, and Cloud Storage APIs.

Roles required to enable APIs

To enable APIs, you need the Service Usage Admin IAM role (roles/serviceusage.serviceUsageAdmin), which contains the serviceusage.services.enable permission. Learn how to grant roles.

Enable the APIs

Installieren Sie die Google Cloud CLI.

Wenn Sie einen externen Identitätsanbieter (IdP) verwenden, müssen Sie sich zuerst mit Ihrer föderierten Identität in der gcloud CLI anmelden.

Führen Sie den folgenden Befehl aus, um die gcloud CLI zu initialisieren:

gcloud init

In the Google Cloud console, on the project selector page, select or create a Google Cloud project.

Roles required to select or create a project

• Select a project: Selecting a project doesn't require a specific IAM role—you can select any project that you've been granted a role on.
• Create a project: To create a project, you need the Project Creator role (roles/resourcemanager.projectCreator), which contains the resourcemanager.projects.create permission. Learn how to grant roles.

Note: If you don't plan to keep the resources that you create in this procedure, create a project instead of selecting an existing project. After you finish these steps, you can delete the project, removing all resources associated with the project.

Go to project selector

Verify that billing is enabled for your Google Cloud project.

Enable the Cloud Functions, Cloud Run, Cloud Build, Artifact Registry, and Cloud Storage APIs.

Roles required to enable APIs

To enable APIs, you need the Service Usage Admin IAM role (roles/serviceusage.serviceUsageAdmin), which contains the serviceusage.services.enable permission. Learn how to grant roles.

Enable the APIs

Installieren Sie die Google Cloud CLI.

Wenn Sie einen externen Identitätsanbieter (IdP) verwenden, müssen Sie sich zuerst mit Ihrer föderierten Identität in der gcloud CLI anmelden.

Führen Sie den folgenden Befehl aus, um die gcloud CLI zu initialisieren:

gcloud init

Wenn Sie die gcloud CLI bereits installiert haben, aktualisieren Sie sie mit dem folgenden Befehl:

gcloud components update

1. Bereiten Sie die Entwicklungsumgebung vor.
   

   Einrichtungsleitfaden für Node.js aufrufen

Erforderliche Rollen

• Nutzer, die Funktionen bereitstellen, müssen die Cloud Functions-Entwickler (roles/cloudfunctions.developer) IAM-Rolle oder eine Rolle mit denselben Berechtigungen haben. Siehe auch Zusätzliche Konfiguration für die Bereitstellung.

• Bitten Sie Ihren Administrator, der IAM-Identität, die die Funktion bereitstellt, die Rolle Storage-Administrator (roles/storage.admin) zu gewähren, um die Berechtigungen für den Zugriff auf den Cloud Storage-Bucket zu erhalten. Weitere Informationen zu Cloud Storage-Rollen und -Berechtigungen finden Sie unter IAM für Cloud Storage.

Umgebung einrichten

In dieser Anleitung führen Sie Befehle in Cloud Shell aus. Cloud Shell ist eine Shell-Umgebung, in der das Google Cloud CLI einschließlich der Google Cloud-Befehlszeile vorinstalliert ist. Auch die Werte für Ihr aktuelles Projekt sind bereits festgelegt. Die Initialisierung von Cloud Shell kann mehrere Minuten dauern:

Cloud Shell öffnen

Anwendung vorbereiten

Führen Sie in Cloud Shell folgende Schritte aus:

1. Klonen Sie das Repository der Beispielanwendung in Ihre Cloud Shell-Instanz:

   git clone https://github.com/terraform-google-modules/terraform-docs-samples.git

2. Wechseln Sie in das Verzeichnis, das die Beispielcodes für Cloud Run-Funktionen enthält:

   cd terraform-docs-samples/functions/basic

   Das in dieser Anleitung verwendete Node.js-Beispiel ist eine grundlegende HTTP-Funktion "Hello World". Hier ist die Datei main.tf:

   terraform {
     required_providers {
       google = {
         source  = "hashicorp/google"
         version = ">= 4.34.0"
       }
     }
   }
   
   resource "random_id" "default" {
     byte_length = 8
   }
   
   resource "google_storage_bucket" "default" {
     name                        = "${random_id.default.hex}-gcf-source" # Every bucket name must be globally unique
     location                    = "US"
     uniform_bucket_level_access = true
   }
   
   data "archive_file" "default" {
     type        = "zip"
     output_path = "/tmp/function-source.zip"
     source_dir  = "functions/hello-world/"
   }
   resource "google_storage_bucket_object" "object" {
     name   = "function-source.zip"
     bucket = google_storage_bucket.default.name
     source = data.archive_file.default.output_path # Add path to the zipped function source code
   }
   
   resource "google_cloudfunctions2_function" "default" {
     name        = "function-v2"
     location    = "us-central1"
     description = "a new function"
   
     build_config {
       runtime     = "nodejs22"
       entry_point = "helloHttp" # Set the entry point
       source {
         storage_source {
           bucket = google_storage_bucket.default.name
           object = google_storage_bucket_object.object.name
         }
       }
     }
   
     service_config {
       max_instance_count = 1
       available_memory   = "256M"
       timeout_seconds    = 60
     }
   }
   
   resource "google_cloud_run_service_iam_member" "member" {
     location = google_cloudfunctions2_function.default.location
     service  = google_cloudfunctions2_function.default.name
     role     = "roles/run.invoker"
     member   = "allUsers"
   }
   
   output "function_uri" {
     value = google_cloudfunctions2_function.default.service_config[0].uri
   }

Terraform initialisieren

Führen Sie im Verzeichnis terraform-docs-samples/functions/basic mit der Datei main.tf diesen Befehl aus, um die erforderlichen Plug-ins hinzuzufügen und das Verzeichnis .terraform zu erstellen:

terraform init

Wenden Sie die Terraform-Konfiguration an:

Stellen Sie die Funktion im selben Verzeichnis terraform-docs-samples/functions/basic mit der Datei main.tf bereit. Wenden Sie dazu die Konfiguration an. Geben Sie bei Aufforderung yes ein:

terraform apply

Funktion testen

1. Notieren Sie sich nach der Bereitstellung der Funktion das Attribut von URI oder suchen Sie es mit diesem Befehl:

   gcloud functions describe function-v2 --gen2 --region=us-central1 --format="value(serviceConfig.uri)"
   

2. Stellen Sie eine Anfrage an diese URL, um die Nachricht "Hello World" Ihrer Funktion zu sehen. Beachten Sie, dass die Funktion implementiert ist und eine Authentifizierung erfordert. Daher müssen Sie in Ihrer Anfrage Anmeldedaten angeben:

   curl -H "Authorization: Bearer $(gcloud auth print-identity-token)" YOUR_FUNCTION_URL

Hinweis: Aus Sicherheitsgründen ist es empfehlenswert, für den Aufruf von HTTP-Funktionen eine Authentifizierung zu verlangen. Bei Bedarf können Sie den nicht authentifizierten Aufruf aktivieren, nachdem die Funktion bereitgestellt wurde.

Bereinigen

Nachdem Sie die Anleitung abgeschlossen haben, können Sie alle erstellten Elemente löschen, sodass keine weiteren Kosten anfallen.

Mit Terraform können Sie alle in der Konfigurationsdatei definierten Ressourcen entfernen. Führen Sie dazu den terraform destroy-Befehl im terraform-docs-samples/functions/basic-Verzeichnis aus, das Ihre main.tf-Datei enthält:

terraform destroy

Geben Sie yes ein, damit Terraform Ihre Ressourcen löschen kann.