Tutorial Pub/Sub Terraform

Tutorial ini menunjukkan cara menerapkan fungsi Pub/Sub dengan mengupload file zip kode sumber fungsi ke bucket Cloud Storage, menggunakan Terraform untuk menyediakan resource. Terraform adalah alat open source yang dapat Anda gunakan untuk menyediakan Google Cloud resource dengan file konfigurasi deklaratif

Tutorial ini menggunakan fungsi Node.js sebagai contoh, tetapi juga dapat digunakan dengan fungsi Python, Go, dan Java. Petunjuknya sama, terlepas dari runtime mana yang Anda gunakan. Lihat halaman referensi Hashicorp untuk mengetahui detail tentang cara menggunakan Terraform dengan Cloud Functions v2 API.

Menyiapkan lingkungan Anda

Dalam tutorial ini, Anda akan menjalankan perintah di Cloud Shell. Cloud Shell adalah lingkungan shell dengan Google Cloud CLI yang sudah terinstal, termasuk Google Cloud CLI, dan dengan nilai yang sudah ditetapkan untuk project Anda saat ini. Cloud Shell dapat memerlukan waktu beberapa menit untuk proses inisialisasi:

Buka Cloud Shell

Menyiapkan aplikasi

Di Cloud Shell, lakukan langkah-langkah berikut:

Clone repositori aplikasi contoh ke instance Cloud Shell Anda:

git clone https://github.com/terraform-google-modules/terraform-docs-samples.git

Ubah ke direktori yang berisi kode contoh fungsi Cloud Run:

cd terraform-docs-samples/functions/pubsub

Contoh Node.js yang digunakan dalam tutorial ini adalah fungsi Pub/Sub "Halo Dunia" dasar. Berikut adalah file main.tf:

terraform {
  required_providers {
    google = {
      source  = "hashicorp/google"
      version = ">= 4.34.0"
    }
  }
}

resource "random_id" "bucket_prefix" {
  byte_length = 8
}


resource "google_service_account" "default" {
  account_id   = "test-gcf-sa"
  display_name = "Test Service Account"
}

resource "google_pubsub_topic" "default" {
  name = "functions2-topic"
}

resource "google_storage_bucket" "default" {
  name                        = "${random_id.bucket_prefix.hex}-gcf-source" # Every bucket name must be globally unique
  location                    = "US"
  uniform_bucket_level_access = true
}

data "archive_file" "default" {
  type        = "zip"
  output_path = "/tmp/function-source.zip"
  source_dir  = "function-source/"
}

resource "google_storage_bucket_object" "default" {
  name   = "function-source.zip"
  bucket = google_storage_bucket.default.name
  source = data.archive_file.default.output_path # Path to the zipped function source code
}

resource "google_cloudfunctions2_function" "default" {
  name        = "function"
  location    = "us-central1"
  description = "a new function"

  build_config {
    runtime     = "nodejs22"
    entry_point = "helloPubSub" # Set the entry point
    environment_variables = {
      BUILD_CONFIG_TEST = "build_test"
    }
    source {
      storage_source {
        bucket = google_storage_bucket.default.name
        object = google_storage_bucket_object.default.name
      }
    }
  }

  service_config {
    max_instance_count = 3
    min_instance_count = 1
    available_memory   = "256M"
    timeout_seconds    = 60
    environment_variables = {
      SERVICE_CONFIG_TEST = "config_test"
    }
    ingress_settings               = "ALLOW_INTERNAL_ONLY"
    all_traffic_on_latest_revision = true
    service_account_email          = google_service_account.default.email
  }

  event_trigger {
    trigger_region = "us-central1"
    event_type     = "google.cloud.pubsub.topic.v1.messagePublished"
    pubsub_topic   = google_pubsub_topic.default.id
    retry_policy   = "RETRY_POLICY_RETRY"
  }
}

Lakukan inisialisasi Terraform

Dalam direktori terraform-docs-samples/functions/pubsub yang berisi file main.tf, jalankan perintah ini untuk menambahkan plugin yang diperlukan dan membuat direktori .terraform:

terraform init

Memvalidasi konfigurasi Terraform

Lihat pratinjau konfigurasi Terraform. Langkah ini bersifat opsional, tetapi memungkinkan Anda memverifikasi bahwa sintaksis main.tf sudah benar. Perintah ini menampilkan pratinjau resource yang akan dibuat:

terraform plan

Menerapkan konfigurasi Terraform

Deploy fungsi dengan menerapkan konfigurasi. Saat diminta, masukkan yes.

terraform apply

Memicu fungsi

Untuk menguji fungsi Pub/Sub:

Memublikasikan pesan ke topik (dalam contoh ini, nama topiknya adalah functions2-topic):
```
gcloud pubsub topics publish TOPIC_NAME --message="Friend"
```
Baca log fungsi untuk melihat hasilnya, dengan FUNCTION_NAME adalah nama fungsi Anda (dalam contoh ini, nama fungsi adalah function):
```
gcloud functions logs read FUNCTION_NAME
```
Anda akan melihat output logging yang menyertakan pesan "Teman" baru.

Catatan: Log mungkin memerlukan waktu beberapa saat untuk ditampilkan. Jika Anda tidak langsung melihatnya, periksa lagi dalam satu atau dua menit.

Pembersihan

Setelah menyelesaikan tutorial, Anda dapat menghapus semua yang telah dibuat sehingga tidak menimbulkan biaya lebih lanjut.

Terraform memungkinkan Anda menghapus semua resource yang ditentukan dalam file konfigurasi dengan menjalankan perintah terraform destroy:

terraform destroy

Masukkan yes untuk mengizinkan Terraform menghapus resource Anda.