Ricezione di eventi mediante messaggi Pub/Sub (Terraform)

Ricezione di eventi mediante messaggi Pub/Sub (Terraform)

Standard

Questa guida rapida mostra come utilizzare Terraform per creare un trigger Eventarc che riceve eventi diretti da Pub/Sub e li indirizza a un servizio Cloud Run. Per ulteriori informazioni sull'utilizzo di Terraform per creare trigger Eventarc, consulta Crea un trigger utilizzando Terraform.

In questa guida rapida imparerai a:

1. Preparati a eseguire il deployment di Terraform.

2. Definisci una configurazione Terraform che esegua le seguenti operazioni:

   1. Abilita le API.
   2. Crea un account di servizio.
   3. Crea un argomento Pub/Sub come fornitore di eventi.
   4. Esegui il deployment di un servizio in Cloud Run come destinazione eventi.
   5. Crea un trigger Eventarc.

3. Applica la configurazione Terraform.

In questo modo puoi generare un evento pubblicando un messaggio nell'argomento Pub/Sub. Il trigger Eventarc indirizza il messaggio al servizio di ricezione di eventi di cui è stato eseguito il deployment su Cloud Run e il servizio registra il messaggio di evento, fornendoti un esempio semplice di un'architettura basata sugli eventi.

Prima di iniziare

I vincoli di sicurezza definiti dalla tua organizzazione potrebbero impedirti di completare i passaggi seguenti. Per informazioni sulla risoluzione dei problemi, vedi Sviluppare applicazioni in un ambiente Google Cloud vincolato.

Accedi al tuo account Google Cloud . Se non conosci Google Cloud, crea un account per valutare le prestazioni dei nostri prodotti in scenari reali. I nuovi clienti ricevono anche 300 $di crediti senza costi per l'esecuzione, il test e il deployment dei workload.

Installa Google Cloud CLI.

Se utilizzi un provider di identità (IdP) esterno, devi prima accedere a gcloud CLI con la tua identità federata.

Per inizializzare gcloud CLI, esegui questo comando:

gcloud init

Crea o seleziona un Google Cloud progetto.

Ruoli richiesti per selezionare o creare un progetto

• Seleziona un progetto: la selezione di un progetto non richiede un ruolo IAM specifico. Puoi selezionare qualsiasi progetto per il quale ti è stato concesso un ruolo.
• Crea un progetto: per creare un progetto, devi disporre del ruolo Autore progetto (roles/resourcemanager.projectCreator), che contiene l'autorizzazione resourcemanager.projects.create. Scopri come concedere i ruoli.

Nota: se non prevedi di conservare le risorse che crei in questa procedura, crea un progetto invece di selezionarne uno già esistente. Una volta completata questa procedura, puoi eliminare il progetto e tutte le relative risorse.

• Creare un progetto Google Cloud :

  gcloud projects create PROJECT_ID

  Sostituisci PROJECT_ID con un nome per il progetto Google Cloud che stai creando.

• Seleziona il progetto Google Cloud che hai creato:

  gcloud config set project PROJECT_ID

  Sostituisci PROJECT_ID con il nome del progetto Google Cloud .

Verifica che la fatturazione sia abilitata per il tuo progetto Google Cloud .

Abilita le API Cloud Resource Manager e Identity and Access Management (IAM):

Ruoli richiesti per abilitare le API

Per abilitare le API, devi disporre del ruolo IAM Amministratore utilizzo dei servizi (roles/serviceusage.serviceUsageAdmin), che include l'autorizzazione serviceusage.services.enable. Scopri come concedere i ruoli.

gcloud services enable cloudresourcemanager.googleapis.com iam.googleapis.com

Se utilizzi una shell locale, crea credenziali di autenticazione locali per il tuo account utente:

gcloud auth application-default login

Non è necessario eseguire questa operazione se utilizzi Cloud Shell.

Se viene restituito un errore di autenticazione e utilizzi un provider di identità (IdP) esterno, verifica di aver acceduto a gcloud CLI con la tua identità federata.

Installa Google Cloud CLI.

Se utilizzi un provider di identità (IdP) esterno, devi prima accedere a gcloud CLI con la tua identità federata.

Per inizializzare gcloud CLI, esegui questo comando:

gcloud init

Crea o seleziona un Google Cloud progetto.

Ruoli richiesti per selezionare o creare un progetto

• Seleziona un progetto: la selezione di un progetto non richiede un ruolo IAM specifico. Puoi selezionare qualsiasi progetto per il quale ti è stato concesso un ruolo.
• Crea un progetto: per creare un progetto, devi disporre del ruolo Autore progetto (roles/resourcemanager.projectCreator), che contiene l'autorizzazione resourcemanager.projects.create. Scopri come concedere i ruoli.

Nota: se non prevedi di conservare le risorse che crei in questa procedura, crea un progetto invece di selezionarne uno già esistente. Una volta completata questa procedura, puoi eliminare il progetto e tutte le relative risorse.

• Creare un progetto Google Cloud :

  gcloud projects create PROJECT_ID

  Sostituisci PROJECT_ID con un nome per il progetto Google Cloud che stai creando.

• Seleziona il progetto Google Cloud che hai creato:

  gcloud config set project PROJECT_ID

  Sostituisci PROJECT_ID con il nome del progetto Google Cloud .

Verifica che la fatturazione sia abilitata per il tuo progetto Google Cloud .

Abilita le API Cloud Resource Manager e Identity and Access Management (IAM):

Ruoli richiesti per abilitare le API

Per abilitare le API, devi disporre del ruolo IAM Amministratore utilizzo dei servizi (roles/serviceusage.serviceUsageAdmin), che include l'autorizzazione serviceusage.services.enable. Scopri come concedere i ruoli.

gcloud services enable cloudresourcemanager.googleapis.com iam.googleapis.com

Se utilizzi una shell locale, crea credenziali di autenticazione locali per il tuo account utente:

gcloud auth application-default login

Non è necessario eseguire questa operazione se utilizzi Cloud Shell.

Se viene restituito un errore di autenticazione e utilizzi un provider di identità (IdP) esterno, verifica di aver acceduto a gcloud CLI con la tua identità federata.

1. Se utilizzi un progetto esistente per questa guida, verifica di disporre delle autorizzazioni necessarie per completare la guida. Se hai creato un nuovo progetto, disponi già delle autorizzazioni necessarie.

   Autorizzazioni obbligatorie

   Per ottenere le autorizzazioni necessarie per completare questa guida rapida, chiedi all'amministratore di concederti i seguenti ruoli IAM nel tuo progetto:

   • Cloud Run Admin (roles/run.admin)
   • Eventarc Admin (roles/eventarc.admin)
   • Logs View Accessor (roles/logging.viewAccessor)
   • Project IAM Admin (roles/resourcemanager.projectIamAdmin)
   • Pub/Sub Publisher (roles/pubsub.publisher)
   • Amministratore service account (roles/iam.serviceAccountAdmin)
   • Utente Service Account (roles/iam.serviceAccountUser)

   Per saperne di più sulla concessione dei ruoli, consulta Gestisci l'accesso a progetti, cartelle e organizzazioni.

   Potresti anche riuscire a ottenere le autorizzazioni richieste tramite i ruoli personalizzati o altri ruoli predefiniti.

Prepararsi a eseguire il deployment di Terraform

Prima di eseguire il deployment di qualsiasi risorsa Terraform, devi creare un file di configurazione Terraform. Un file di configurazione Terraform ti consente di definire lo stato finale preferito per la tua infrastruttura utilizzando la sintassi Terraform.

1. Se utilizzi una shell locale, installa Terraform.

   Terraform è già integrato nell'ambiente Cloud Shell e puoi utilizzare Cloud Shell per eseguire il deployment delle risorse Terraform senza dover installare Terraform.

2. In Cloud Shell o nella shell locale, imposta il Google Cloud progetto predefinito in cui vuoi applicare la configurazione Terraform. Devi eseguire questo comando una sola volta per progetto e puoi eseguirlo in qualsiasi directory:

   export GOOGLE_CLOUD_PROJECT=PROJECT_ID

   Sostituisci PROJECT_ID con l'ID del tuo progetto Google Cloud .

   Tieni presente che le variabili di ambiente vengono sostituite se imposti valori espliciti nel file di configurazione Terraform.

3. Ogni file di configurazione Terraform deve avere la propria directory (chiamata anche modulo radice). Crea una directory e un nuovo file al suo interno:

   mkdir DIRECTORY && cd DIRECTORY && touch main.tf

   Sostituisci DIRECTORY con il nome della directory Terraform.

   Il nome file deve avere l'estensione .tf. Ad esempio, in questa guida rapida, il file di configurazione è main.tf.

Definisci la configurazione Terraform

Copia i seguenti snippet di codice Terraform nel file main.tf. In alternativa, per copiare l'intero esempio di codice da GitHub, fai clic su > Visualizza su GitHub nell'angolo in alto a destra di uno snippet di codice.

Abilita API

Per abilitare le API necessarie per applicare la configurazione Terraform, utilizza la risorsa Terraform google_project_service:

# Enable Cloud Run API
resource "google_project_service" "run" {
  service            = "run.googleapis.com"
  disable_on_destroy = false
}

# Enable Eventarc API
resource "google_project_service" "eventarc" {
  service            = "eventarc.googleapis.com"
  disable_on_destroy = false
}

# Enable Pub/Sub API
resource "google_project_service" "pubsub" {
  service            = "pubsub.googleapis.com"
  disable_on_destroy = false
}

Crea un account di servizio

Ogni trigger Eventarc è associato a un account di servizio IAM. Per creare un account di servizio dedicato a scopo di test, utilizza la risorsa Terraform google_service_account:

# Create a dedicated service account
resource "google_service_account" "eventarc" {
  account_id   = "eventarc-trigger-sa"
  display_name = "Eventarc trigger service account"
}

Se hai attivato l'agente di servizio Pub/Sub l'8 aprile 2021 o in una data precedente, concedi il ruolo Creatore token account di servizio (roles/iam.serviceAccountTokenCreator) all'agente di servizio.

resource "google_project_iam_member" "tokencreator" {
  project  = data.google_project.project.id
  role     = "roles/iam.serviceAccountTokenCreator"
  member   = "serviceAccount:service-${data.google_project.project.number}@gcp-sa-pubsub.iam.gserviceaccount.com"
}

Crea un argomento Pub/Sub come fornitore di eventi

Per creare un argomento Pub/Sub, utilizza la risorsa Terraform google_pubsub_topic. Per concedere al tuo account di servizio il ruolo Pub/Sub Publisher (roles/pubsub.publisher) a livello di argomento, utilizza la risorsa Terraform google_pubsub_topic_iam_member:

# Create a Pub/Sub topic
resource "google_pubsub_topic" "default" {
  name = "pubsub_topic"
}

# Grant permission to publish messages to a Pub/Sub topic
resource "google_pubsub_topic_iam_member" "pubsubpublisher" {
  project    = google_pubsub_topic.default.project
  topic      = google_pubsub_topic.default.name
  member     = "serviceAccount:${google_service_account.eventarc.email}"
  role       = "roles/pubsub.publisher"
  depends_on = [google_pubsub_topic.default]
}

Esegui il deployment di un ricevitore di eventi in Cloud Run

Per creare un servizio Cloud Run come destinazione evento, utilizza la risorsa Terraform google_cloud_run_v2_service. Per concedere al tuo account di servizio il ruolo Cloud Run Invoker (roles/run.invoker) a livello di servizio, utilizza la risorsa google_cloud_run_v2_service_iam_member Terraform:

# Deploy a Cloud Run service
resource "google_cloud_run_v2_service" "default" {
  name     = "hello-events"
  location = "us-central1"

  deletion_protection = false # set to "true" in production

  template {
    containers {
      # This sample container listens to HTTP requests and logs received events
      image = "us-docker.pkg.dev/cloudrun/container/hello"
    }
    service_account = google_service_account.eventarc.email
  }

  depends_on = [google_project_service.run]
}

# Grant permission to invoke Cloud Run services
resource "google_cloud_run_v2_service_iam_member" "runinvoker" {
  project    = google_cloud_run_v2_service.default.project
  location   = google_cloud_run_v2_service.default.location
  name       = google_cloud_run_v2_service.default.name
  role       = "roles/run.invoker"
  member     = "serviceAccount:${google_service_account.eventarc.email}"
  depends_on = [google_cloud_run_v2_service.default]
}

Crea un trigger Eventarc

Per creare un trigger Eventarc che ascolti i messaggi Pub/Sub, utilizza la risorsa Terraform google_eventarc_trigger:

# Create an Eventarc trigger, routing Pub/Sub events to Cloud Run
resource "google_eventarc_trigger" "default" {
  name     = "trigger-pubsub-cloudrun-tf"
  location = google_cloud_run_v2_service.default.location

  # Capture messages published to a Pub/Sub topic
  matching_criteria {
    attribute = "type"
    value     = "google.cloud.pubsub.topic.v1.messagePublished"
  }

  # Send events to Cloud Run
  destination {
    cloud_run_service {
      service = google_cloud_run_v2_service.default.name
      region  = google_cloud_run_v2_service.default.location
    }
  }

  transport {
    pubsub {
      topic = google_pubsub_topic.default.id
    }
  }

  service_account = google_service_account.eventarc.email
  depends_on = [
    google_project_service.eventarc,
    google_pubsub_topic_iam_member.pubsubpublisher
  ]
}

Nota: anche se il trigger viene creato immediatamente, potrebbero essere necessari fino a due minuti prima che sia completamente funzionante.

Applica la configurazione Terraform

Utilizza l'interfaccia a riga di comando di Terraform per eseguire il provisioning dell'infrastruttura in base al file di configurazione. Per saperne di più, consulta Comandi Terraform di base.

1. Inizializza Terraform. Devi farlo solo una volta per directory.

   terraform init

   (Facoltativo) Per utilizzare l'ultima versione del provider Google, includi l'opzione -upgrade:

   terraform init -upgrade

2. Rivedi la configurazione e verifica che le risorse che Terraform creerà o aggiornerà corrispondano alle tue aspettative:

   terraform plan

   Correggi la configurazione in base alle esigenze.

3. Applica la configurazione Terraform eseguendo il seguente comando e inserendo yes al prompt:

   terraform apply

   In genere, applichi l'intera configurazione contemporaneamente. Tuttavia, puoi anche scegliere come target una risorsa specifica. Ad esempio:

   terraform apply -target="google_eventarc_trigger.default"

   Dopo aver abilitato le API, potrebbero essere necessari alcuni minuti prima che l'azione venga propagata e tu possa eseguire il deployment di altre risorse. Se riscontri un problema, prova ad applicare di nuovo la configurazione Terraform.

   Attendi che Terraform visualizzi il messaggio "Apply complete!".

Verifica la creazione delle risorse

1. Verifica che il servizio Cloud Run sia stato creato:

   gcloud run services list --region us-central1
   

   L'output dovrebbe essere simile al seguente:

   SERVICE: hello-events
   REGION: us-central1
   URL: https://hello-events-13335919645.us-central1.run.app
   LAST DEPLOYED BY: ...
   LAST DEPLOYED AT: 2024-12-16T15:00:52.606160Z
   

2. Verifica che il trigger Eventarc sia stato creato:

   gcloud eventarc triggers list --location us-central1
   

   L'output dovrebbe essere simile al seguente:

   NAME: trigger-pubsub-cloudrun-tf
   TYPE: google.cloud.pubsub.topic.v1.messagePublished
   DESTINATION: Cloud Run service: hello-events
   ACTIVE: Yes
   LOCATION: us-central1
   

Generare e visualizzare un evento dell'argomento Pub/Sub

Puoi generare un evento pubblicando un messaggio nell'argomento Pub/Sub. Il trigger Eventarc instrada il messaggio al servizio di ricezione di eventi di cui è stato eseguito il deployment su Cloud Run e il servizio registra il messaggio di evento.

1. Trova e imposta l'argomento Pub/Sub come variabile di ambiente:

   gcloud config set eventarc/location us-central1
   export RUN_TOPIC=$(gcloud eventarc triggers describe trigger-pubsub-cloudrun-tf \
       --format='value(transport.pubsub.topic)')
   

2. Per generare un evento, pubblica un messaggio nell'argomento Pub/Sub:

   gcloud pubsub topics publish $RUN_TOPIC --message "Hello World!"
   

   L'evento viene indirizzato al servizio Cloud Run, che registra il messaggio dell'evento.

3. Filtra le voci di log create dal tuo servizio:

   gcloud logging read 'jsonPayload.message: "Received event of type google.cloud.pubsub.topic.v1.messagePublished"'
   

4. Cerca una voce di log simile alla seguente:

   jsonPayload:
   ...
   message: 'Received event of type google.cloud.pubsub.topic.v1.messagePublished.
       Event data: Hello World!'
   

   Nota: se non vedi una voce di log, attendi qualche minuto e riprova il comando gcloud logging read.

Hai utilizzato correttamente Terraform per eseguire il deployment di un servizio di ricezione eventi in Cloud Run e creare un trigger Eventarc. Dopo aver generato un evento da Pub/Sub, puoi visualizzarlo nei log di Cloud Run.

Esegui la pulizia

Al termine delle attività descritte in questa guida rapida, puoi evitare l'addebito di ulteriori costi eliminando le risorse che hai creato.

Rimuovi le risorse applicate in precedenza con la configurazione Terraform eseguendo il comando seguente e inserendo yes al prompt:

terraform destroy

In alternativa, puoi eliminare il tuo progetto Google Cloud per evitare addebiti. L'eliminazione del tuo progetto Google Cloud interrompe la fatturazione per tutte le risorse utilizzate al suo interno.

Attenzione: l'eliminazione di un progetto ha i seguenti effetti:

• L'intero contenuto del progetto viene eliminato. Se hai utilizzato un progetto esistente per, le attività descritte in questo documento, eliminerai anche tutto il lavoro che hai svolto nel progetto.
• Gli ID progetto personalizzati non sono più disponibili. Quando hai creato questo progetto, potresti aver creato un ID progetto personalizzato che vuoi utilizzare in futuro. Per conservare gli URL che utilizzano l'ID progetto, ad esempio un URL appspot.com, elimina le risorse selezionate all'interno del progetto anziché eliminare l'intero progetto.

Elimina un progetto Google Cloud :

gcloud projects delete PROJECT_ID

Se intendi esplorare più tutorial e guide rapide, il riuso dei progetti ti aiuta a non superare i limiti di quota.

Passaggi successivi

• Sviluppa servizi per Cloud Run
• Documentazione di Terraform su Google Cloud