버스 및 등록을 만들어 이벤트 게시 및 수신 (Terraform)

버스 및 등록을 만들어 이벤트 게시 및 수신 (Terraform)

고급

이 빠른 시작에서는 Terraform을 사용하여 Google Cloud 프로젝트에 Eventarc Advanced 버스 및 등록을 만들어 이벤트 메시지를 게시하고 수신하는 방법을 보여줍니다.

• 버스는 중앙 라우터 역할을 하며 이벤트 소스에서 메시지를 수신하거나 제공업체에서 게시합니다.

• 등록은 버스에서 수신한 메시지를 처리 파이프라인을 통해 하나 이상의 대상으로 라우팅합니다.

이 빠른 시작에서는 다음을 수행합니다.

1. Cloud Run에 이벤트 수신자 서비스를 배포합니다.

2. Eventarc Advanced 버스를 만듭니다.

3. Google 소스의 이벤트를 사용 설정합니다.

4. Eventarc Advanced 파이프라인 및 등록을 만듭니다.

5. 워크플로를 만들어 버스에 이벤트 메시지를 게시합니다.

6. Cloud Run 로그에서 이벤트 데이터를 확인합니다.

Terraform을 사용하여 이 빠른 시작의 대부분의 단계를 완료할 수 있습니다. Google Cloud CLI를 사용하여 모든 단계를 완료하려면 Google 소스에서 이벤트 게시를 참고하세요.

Terraform 사용에 대한 자세한 내용은 Google Cloud의 Terraform 문서를 참고하세요.

시작하기 전에

조직에서 정의한 보안 제약조건으로 인해 다음 단계를 완료하지 못할 수 있습니다. 문제 해결 정보는 제한된 Google Cloud 환경에서 애플리케이션 개발을 참조하세요.

Google Cloud 계정에 로그인합니다. Google Cloud를 처음 사용하는 경우 계정을 만들고 Google 제품의 실제 성능을 평가해 보세요. 신규 고객에게는 워크로드를 실행, 테스트, 배포하는 데 사용할 수 있는 $300의 무료 크레딧이 제공됩니다.

In the Google Cloud console, on the project selector page, select or create a Google Cloud project.

Roles required to select or create a project

• Select a project: Selecting a project doesn't require a specific IAM role—you can select any project that you've been granted a role on.
• Create a project: To create a project, you need the Project Creator role (roles/resourcemanager.projectCreator), which contains the resourcemanager.projects.create permission. Learn how to grant roles.

Note: If you don't plan to keep the resources that you create in this procedure, create a project instead of selecting an existing project. After you finish these steps, you can delete the project, removing all resources associated with the project.

Go to project selector

If you're using an existing project for this guide, verify that you have the permissions required to complete this guide. If you created a new project, then you already have the required permissions.

Verify that billing is enabled for your Google Cloud project.

Enable the Cloud Resource Manager and Identity and Access Management (IAM) APIs, if any are not already enabled.

Roles required to enable APIs

To enable APIs, you need the serviceusage.services.enable permission. If you created the project, then you likely already have this permission through the Owner role (roles/owner). Otherwise, you can get this permission through the Service Usage Admin role (roles/serviceusage.serviceUsageAdmin). Learn how to grant roles.

Enable the APIs

In the Google Cloud console, on the project selector page, select or create a Google Cloud project.

Roles required to select or create a project

• Select a project: Selecting a project doesn't require a specific IAM role—you can select any project that you've been granted a role on.
• Create a project: To create a project, you need the Project Creator role (roles/resourcemanager.projectCreator), which contains the resourcemanager.projects.create permission. Learn how to grant roles.

Note: If you don't plan to keep the resources that you create in this procedure, create a project instead of selecting an existing project. After you finish these steps, you can delete the project, removing all resources associated with the project.

Go to project selector

If you're using an existing project for this guide, verify that you have the permissions required to complete this guide. If you created a new project, then you already have the required permissions.

Verify that billing is enabled for your Google Cloud project.

Enable the Cloud Resource Manager and Identity and Access Management (IAM) APIs, if any are not already enabled.

Roles required to enable APIs

To enable APIs, you need the serviceusage.services.enable permission. If you created the project, then you likely already have this permission through the Owner role (roles/owner). Otherwise, you can get this permission through the Service Usage Admin role (roles/serviceusage.serviceUsageAdmin). Learn how to grant roles.

Enable the APIs

1. Google Cloud 콘솔에서 Cloud Shell을 활성화합니다.

   Cloud Shell 활성화

   Google Cloud 콘솔 하단에서 Cloud Shell 세션이 시작되고 명령줄 프롬프트가 표시됩니다. Cloud Shell은 Google Cloud CLI가 사전 설치된 셸 환경으로, 현재 프로젝트의 값이 이미 설정되어 있습니다. 세션이 초기화되는 데 몇 초 정도 걸릴 수 있습니다.

Terraform은 Cloud Shell 환경에 통합되어 있으며 Terraform을 설치하지 않고도 Cloud Shell을 사용하여 Terraform 리소스를 배포할 수 있습니다.

필요한 역할

빠른 시작을 완료하는 데 필요한 권한을 얻으려면 관리자에게 프로젝트에 대한 다음 IAM 역할을 부여해 달라고 요청하세요.

• Cloud Run 관리자 (roles/run.admin)
• Eventarc 개발자 (roles/eventarc.developer)
• Eventarc 메시지 버스 관리자 (roles/eventarc.messageBusAdmin)
• 로그 뷰 접근자 (roles/logging.viewAccessor)
• 프로젝트 IAM 관리자 (roles/resourcemanager.projectIamAdmin)
• 서비스 계정 관리자 (roles/iam.serviceAccountAdmin)
• 서비스 계정 사용자(roles/iam.serviceAccountUser)
• 워크플로 편집자 (roles/workflows.editor)

역할 부여에 대한 자세한 내용은 프로젝트, 폴더, 조직에 대한 액세스 관리를 참조하세요.

커스텀 역할이나 다른 사전 정의된 역할을 통해 필요한 권한을 얻을 수도 있습니다.

Terraform 배포 준비

Terraform 리소스를 배포하기 전에 Terraform 구성 파일을 만들어야 합니다. Terraform 구성 파일을 사용하면 Terraform 구문을 사용하여 인프라에 대해 원하는 최종 상태를 정의할 수 있습니다.

1. Cloud Shell에서 Terraform 구성을 적용할 기본 Google Cloud 프로젝트를 설정합니다. 이 명령어는 프로젝트당 한 번만 실행하면 되며 어떤 디렉터리에서도 실행할 수 있습니다.

   export GOOGLE_CLOUD_PROJECT=PROJECT_ID

   PROJECT_ID를 Google Cloud 프로젝트의 ID로 바꿉니다.

   Terraform 구성 파일에서 명시적 값을 설정하면 환경 변수가 재정의됩니다.

2. 각 Terraform 구성 파일에는 자체 디렉터리(루트 모듈이라고도 함)가 있어야 합니다. Cloud Shell에서 디렉터리를 만들고 해당 디렉터리 내에 새 파일을 만듭니다.

   mkdir DIRECTORY && cd DIRECTORY && touch main.tf

   DIRECTORY을 Terraform 디렉터리의 이름으로 바꿉니다.

   파일 이름에는 .tf 확장자가 있어야 합니다. 예를 들어 이 빠른 시작에서는 구성 파일이 main.tf입니다.

Terraform 구성 정의

다음 Terraform 코드 스니펫을 main.tf 파일에 복사합니다. 또는 GitHub에서 전체 코드 샘플을 복사하려면 코드 스니펫의 오른쪽 상단에서 > GitHub에서 보기를 클릭합니다.

API 사용 설정

google_project_service Terraform 리소스를 사용하여 Terraform 구성을 적용하는 데 필요한 API를 사용 설정합니다.

# Enable APIs
resource "google_project_service" "apis" {
  for_each = toset([
    "eventarc.googleapis.com",
    "eventarcpublishing.googleapis.com",
    "run.googleapis.com"
  ])
  service            = each.key
  disable_on_destroy = false
}

서비스 계정 만들기

테스트 목적으로 전용 서비스 계정을 만들고 특정 IAM 역할을 부여합니다.

google_service_account 및 google_project_iam_member Terraform 리소스를 사용하여 서비스 계정을 만들고 이벤트를 게시하고 수신하는 데 필요한 역할을 부여합니다.

# Used to retrieve project information later
data "google_project" "project" {}

# Create a dedicated service account
resource "google_service_account" "default" {
  account_id   = "eventarc-advanced-sa"
  display_name = "Eventarc Advanced quickstart service account"
}

# Grant permission to receive Eventarc events
resource "google_project_iam_member" "eventreceiver" {
  project = data.google_project.project.id
  role    = "roles/eventarc.eventReceiver"
  member  = "serviceAccount:${google_service_account.default.email}"
}

# Grant permission to invoke Cloud Run services
resource "google_project_iam_member" "runinvoker" {
  project = data.google_project.project.id
  role    = "roles/run.invoker"
  member  = "serviceAccount:${google_service_account.default.email}"
}

이벤트 대상 만들기

google_cloud_run_v2_service Terraform 리소스를 사용하여 이벤트 콘텐츠를 로깅하는 Cloud Run 서비스를 이벤트 대상으로 만듭니다.

# Deploy Cloud Run service
resource "google_cloud_run_v2_service" "default" {
  name     = "example-service"
  location = "us-central1"

  deletion_protection = false # set to "true" in production

  template {
    containers {
      # This sample container listens to HTTP requests and logs received events
      image = "us-docker.pkg.dev/cloudrun/container/hello"
    }
    service_account = google_service_account.default.email
  }

  depends_on = [google_project_service.apis]
}

Eventarc Advanced 버스 만들기

버스는 메시지 소스에서 수신하거나 제공자에서 게시한 이벤트 메시지를 수신하며 메시지 라우터 역할을 합니다. 자세한 내용은 메시지 라우팅을 위한 버스 만들기를 참조하세요.

참고: Google Cloud 프로젝트당 지원되는 리전별로 버스를 하나씩 만들 수 있습니다.

google_eventarc_message_bus Terraform 리소스를 사용하여 Eventarc Advanced 버스를 만듭니다.

# Create an Eventarc Advanced bus
resource "google_eventarc_message_bus" "default" {
  location       = "us-central1"
  message_bus_id = "example-bus"
}

Google 소스에서 이벤트 사용 설정

Google 소스에서 이벤트를 게시하려면 특정 Eventarc Advanced 버스의 Google API 이벤트 구독을 나타내는 GoogleApiSource 리소스를 만들어야 합니다. 자세한 내용은 Google 소스에서 이벤트 게시를 참조하세요.

참고: 지원되는 리전별로 Google Cloud프로젝트당 하나의 GoogleApiSource 리소스를 만들 수 있습니다.

google_eventarc_google_api_source Terraform 리소스를 사용하여 Google 소스의 이벤트를 사용 설정합니다.

# Enable events from Google API sources
resource "google_eventarc_google_api_source" "default" {
  location             = "us-central1"
  google_api_source_id = "example-google-api-source"
  destination          = google_eventarc_message_bus.default.id
}

이제 Google 소스에서 직접 전송되는 모든 지원되는 Google 이벤트 유형이 수집되어 버스에 게시됩니다.

Eventarc Advanced 파이프라인 만들기

파이프라인을 사용하면 대상 대상을 구성할 수 있으며 일치하는 이벤트를 대상에 전송하기 전에 변환할 수 있는 옵션도 제공됩니다.

google_eventarc_pipeline Terraform 리소스를 사용하여 파이프라인을 만듭니다.

# Create an Eventarc Advanced pipeline
resource "google_eventarc_pipeline" "default" {
  location    = "us-central1"
  pipeline_id = "example-pipeline"
  destinations {
    http_endpoint {
      uri = google_cloud_run_v2_service.default.uri
    }
    authentication_config {
      google_oidc {
        service_account = google_service_account.default.email
      }
    }
  }
}

이벤트 대상은 Cloud Run 서비스의 정규화된 URL입니다(예: https://SERVICE_NAME-abcdef-uc.a.run.app). 서비스 계정 이메일 주소는 OIDC 토큰을 생성하는 데 사용됩니다.

참고: 파이프라인을 만드는 데 몇 분 정도 걸릴 수 있습니다.

Eventarc Advanced 등록 만들기

등록은 대상에 라우팅되는 메시지를 결정하며, 이벤트 메시지의 대상을 구성하는 데 사용되는 파이프라인도 지정합니다. 자세한 내용은 이벤트를 수신하도록 등록 만들기를 참조하세요.

google_eventarc_enrollment Terraform 리소스를 사용하여 등록을 만듭니다.

# Create an Eventarc Advanced enrollment
resource "google_eventarc_enrollment" "default" {
  location      = "us-central1"
  enrollment_id = "example-enrollment"
  message_bus   = google_eventarc_message_bus.default.id
  destination   = google_eventarc_pipeline.default.id
  cel_match     = "message.type == 'google.cloud.workflows.workflow.v1.created'"
}

등록의 일치 표현식은 워크플로가 생성될 때마다 이벤트 메시지를 게시하기 위해 Common Expression Language (CEL)를 사용합니다. 다음 단계에서는 워크플로를 만듭니다.

Terraform 구성 적용

Terraform CLI를 사용하여 구성 파일을 기반으로 인프라를 프로비저닝합니다. 자세한 내용은 기본 Terraform 명령어를 참고하세요.

1. Terraform을 초기화합니다. 이 작업은 디렉터리당 한 번만 수행하면 됩니다.

   terraform init

   원하는 경우 최신 Google 공급업체 버전을 사용하려면 -upgrade 옵션을 포함합니다.

   terraform init -upgrade

2. 구성을 검토하고 Terraform에서 만들거나 업데이트할 리소스가 예상과 일치하는지 확인합니다.

   terraform plan

   필요에 따라 구성을 수정합니다.

3. 다음 명령어를 실행하고 프롬프트에 yes를 입력하여 Terraform 구성을 적용합니다.

   terraform apply

   일반적으로 전체 구성을 한 번에 적용합니다. 하지만 특정 리소스를 타겟팅할 수도 있습니다. 예를 들면 다음과 같습니다.

   terraform apply -target="google_eventarc_message_bus.default"

   Terraform에 '적용 완료' 메시지가 표시될 때까지 기다립니다.

워크플로를 만들어 버스에 이벤트 메시지 게시

Workflows는 워크플로라는 정의된 순서로 서비스를 실행하는 완전 관리형 조정 플랫폼입니다. Google 소스에서 지원되는 이벤트 유형을 생성하는 워크플로를 만듭니다.

1. 홈 디렉터리에서 myWorkflow.yaml이라는 이름의 새 파일을 만듭니다.

2. 다음 워크플로를 복사하여 새 파일에 붙여넣은 후 저장하세요.

   main:
       params: [input]
       steps:
       - checkSearchTermInInput:
           switch:
               - condition: '${"searchTerm" in input}'
                 assign:
                   - searchTerm: '${input.searchTerm}'
                 next: readWikipedia
       - getLocation:
           call: sys.get_env
           args:
               name: GOOGLE_CLOUD_LOCATION
           result: location
       - setFromCallResult:
           assign:
               - searchTerm: '${text.split(location, "-")[0]}'
       - readWikipedia:
           call: http.get
           args:
               url: 'https://en.wikipedia.org/w/api.php'
               query:
                   action: opensearch
                   search: '${searchTerm}'
           result: wikiResult
       - returnOutput:
               return: '${wikiResult.body[1]}'
   

   이 워크플로는 워크플로가 배포된 리전을 Wikipedia API에 전달하고 관련 Wikipedia 문서 목록을 반환합니다.

3. gcloud workflows deploy 명령어를 사용하여 워크플로를 배포합니다.

   gcloud workflows deploy example-workflow --source=myWorkflow.yaml \
       --service-account=eventarc-advanced-sa@PROJECT_ID.iam.gserviceaccount.com \
       --location=us-central1

Cloud Run 로그에서 이벤트 데이터 확인

Eventarc Advanced 버스에 이벤트를 게시한 후 Cloud Run 서비스의 로그를 확인하여 이벤트가 예상대로 수신되었는지 확인할 수 있습니다.

1. 서비스에서 만든 로그 항목을 필터링합니다.

   gcloud logging read 'jsonPayload.message: "Received event of type google.cloud.workflows.workflow.v1.created."'
   

2. 다음과 같은 로그 항목을 찾습니다.

   message: 'Received event of type google.cloud.workflows.workflow.v1.created.
   Event data: {"@type":"type.googleapis.com/google.events.cloud.workflows.v1.WorkflowEventData","payload":{"name":"projects/PROJECT_ID/locations/us-central1/workflows/example-workflow","state":"ACTIVE"...
   

참고: 로그 항목이 표시되지 않으면 몇 분 정도 기다린 후 gcloud logging read 명령어를 다시 시도합니다.

Eventarc Advanced 버스 및 등록을 만들고, Google 소스에서 이벤트 게시를 사용 설정하고, Google 프로바이더에서 지원되는 이벤트 유형을 생성하는 워크플로를 만든 다음, 이벤트 수신자 서비스의 로그에서 예상 결과를 확인했습니다.

삭제

다음 명령어를 실행하고 프롬프트에 yes를 입력하여 이전에 Terraform 구성에 적용된 리소스를 삭제합니다.

terraform destroy

비용이 청구되지 않도록 Google Cloud 프로젝트를 삭제할 수도 있습니다. Google Cloud 프로젝트를 삭제하면 해당 프로젝트 내에서 사용되는 모든 리소스에 대한 청구가 중단됩니다.

주의: 프로젝트를 삭제하면 다음과 같은 결과가 발생합니다.
• 프로젝트의 모든 항목이 삭제됩니다. 이 문서의 태스크에 기존 프로젝트를 사용한 경우 프로젝트를 삭제하면 프로젝트에서 수행한 다른 작업도 삭제됩니다.
• 커스텀 프로젝트 ID가 손실됩니다. 이 프로젝트를 만들 때 앞으로 사용할 커스텀 프로젝트 ID를 만들었을 수 있습니다. appspot.com URL과 같이 프로젝트 ID를 사용하는 URL을 보존하려면 전체 프로젝트를 삭제하는 대신 프로젝트 내에서 선택한 리소스만 삭제합니다.
1. Google Cloud 콘솔에서 리소스 관리 페이지로 이동합니다.

   리소스 관리로 이동

2. 프로젝트 목록에서 삭제할 프로젝트를 선택하고 삭제를 클릭합니다.
3. 대화상자에서 프로젝트 ID를 입력한 후 종료를 클릭하여 프로젝트를 삭제합니다.

다음 단계

• 이벤트 직접 게시
• 수신된 이벤트 변환
• 수신된 이벤트 형식 지정