测试数据质量

本文档介绍了如何使用 Dataform创建 Dataform 表断言并测试工作流代码。

关于断言

断言是一种数据质量测试查询，用于查找违反查询中指定的一个或多个条件的行。如果查询返回任何行，则断言失败。Dataform 会在每次更新工作流时运行断言，并在任何断言失败时提醒您。

Dataform 会在 BigQuery 中自动创建视图，其中包含已编译断言查询的结果。如工作流设置文件中所配置的那样，Dataform 会在断言架构中创建这些视图，您可以在其中检查断言结果。

例如，对于默认的 dataform_assertions 架构，Dataform 会在 BigQuery 中创建以下格式的视图： dataform_assertions.assertion_name。

您可以为所有 Dataform 表类型（表、增量表、视图和具体化视图）创建断言。

您可以通过以下方式创建断言：

准备工作

  1. 在 Google Cloud 控制台中，前往 Dataform 页面。

    前往 Dataform 页面

  2. 选择或创建代码库。

  3. 选择或创建开发工作区。

  4. 创建表。

所需角色

如需获得创建断言所需的权限，请让您的管理员向您授予工作区的 Dataform Editor (roles/dataform.editor) IAM 角色。如需详细了解如何授予角色，请参阅管理对项目、文件夹和组织的访问权限。

您也可以通过自定义 角色或其他预定义 角色来获取所需的权限。

创建内置断言

您可以将内置 Dataform 断言添加到表的 config 块。Dataform 会在创建表后运行这些断言。Dataform 创建表后，您可以在工作区的工作流执行日志 标签页中查看断言是否通过。

您可以在表的 config 块中创建以下断言：

  • nonNull

    此条件断言指定列在所有表行中均不为 null。此条件适用于永远不能为 null 的列。

    以下代码示例展示了表的 config 块中的 nonNull 断言：

config {
  type: "table",
  assertions: {
    nonNull: ["user_id", "customer_id", "email"]
  }
}
SELECT ...

  • rowConditions

    此条件断言所有表行都遵循您定义的自定义逻辑。每个行条件都是一个自定义 SQL 表达式，并且每个表行都会根据每个行条件进行评估。如果任何表行的结果为 false，则断言失败。

    以下代码示例展示了增量表的 config 块中的自定义 rowConditions 断言：

config {
  type: "incremental",
  assertions: {
    rowConditions: [
      'signup_date is null or signup_date > "2022-08-01"',
      'email like "%@%.%"'
    ]
  }
}
SELECT ...

  • uniqueKey

    此条件断言在指定列中，没有表行具有相同的值。

    以下代码示例展示了视图的 config 块中的 uniqueKey 断言：

config {
  type: "view",
  assertions: {
    uniqueKey: ["user_id"]
  }
}
SELECT ...

  • uniqueKeys

    此条件断言在指定列中，没有表行具有相同的值。如果表中有多行在所有指定列中具有相同的值，则断言失败。

    以下代码示例展示了表的 config 块中的 uniqueKeys 断言：

config {
  type: "table",
  assertions: {
    uniqueKeys: [["user_id"], ["signup_date", "customer_id"]]
  }
}
SELECT ...

将断言添加到 config 块

如需将断言添加到表的配置块，请按照以下步骤操作：

  1. 在开发工作区的文件 窗格中，选择表定义 SQLX 文件。
  2. 在表文件的 config 块中，输入 assertions: {}。
  3. 在 assertions: {} 中，添加您的断言。
  4. 可选：点击格式化 。

以下代码示例展示了在 config 块中添加的条件：

config {
  type: "table",
  assertions: {
    uniqueKey: ["user_id"],
    nonNull: ["user_id", "customer_id"],
    rowConditions: [
      'signup_date is null or signup_date > "2019-01-01"',
      'email like "%@%.%"'
    ]
  }
}
SELECT ...

使用 SQLX 创建手动断言

手动断言是在专用 SQLX 文件中编写的 SQL 查询。手动断言 SQL 查询必须返回零行。如果查询在运行时返回行，则断言失败。

如需在新的 SQLX 文件中添加手动断言，请按照以下步骤操作：

  1. 在文件 窗格中，点击 definitions/ 旁边的 更多 菜单。
  2. 点击创建文件 。

  3. 在添加文件路径 字段中，输入文件名，后跟 .sqlx。例如，definitions/custom_assertion.sqlx。

    文件名只能包含数字、字母、连字符和下划线。

  4. 点击创建文件 。

  5. 在文件 窗格中，点击新文件。

  6. 在该文件中，输入：

    config {
  type: "assertion"
}

  7. 在 config 块下方，编写 SQL 查询或多个查询。

  8. 可选：点击格式化 。

以下代码示例展示了 SQLX 文件中的手动断言，该断言断言 字段 A、B 和 c 永远不为 NULL：sometable

config { type: "assertion" }

SELECT
  *
FROM
  ${ref("sometable")}
WHERE
  a IS NULL
  OR b IS NULL
  OR c IS NULL

后续步骤